Question

Can anyone explain how I can successfully get my processes communicating? I find the perldoc on IPC confusing.

What I have so far is:

$| = 1;
$SIG{CHLD} = {wait};
my $parentPid = $$;

if ($pid = fork();) ) {
    if ($pid == 0) {
       pipe($parentPid, $$);
       open PARENT, "<$parentPid";
       while (<PARENT>) {
           print $_;
       }
       close PARENT;
       exit();
    } else {

       pipe($parentPid, $pid);
       open CHILD, ">$pid";
          or error("\nError opening: childPid\nRef: $!\n");
       open (FH, "<list")
          or error("\nError opening: list\nRef: $!\n");

       while(<FH>) {
          print CHILD, $_;
       }

       close FH
          or error("\nError closing: list\nRef: $!\n");
       close CHILD
          or error("\nError closing: childPid\nRef: $!\n);
    } else {
    error("\nError forking\nRef: $!\n");
}

• First: What does perldoc pipe mean by READHANDLE, WRITEHANDLE?

• Second: Can I implement a solution without relying on CPAN or other modules?

_{(source: wellho.net)}

Answer 1

Here is a simplified example based on code found in perldoc perlipc:

#!/usr/bin/perl

use strict; use warnings;

$SIG{CHLD} = sub { wait };

pipe my $reader, my $writer;

my $pid = fork;
defined $pid or die "fork failed: $!";

if ( $pid ) { # parent
    close $reader;
    for my $n ( 1 .. 5 ) {
        select $writer;
        $| = 1;
        print $writer "Message $n\n"
            or die "Failed to pass message to child: $!";
        sleep 1;
    }
    close $writer;
    exit;
}
else { # child
    close $writer;
    while ( my $msg = <$reader> ) {
        print "Child received: $msg";
        last if rand > 0.5; # to check error handling in parent
    }
    close $reader;
    exit;
}