Question

First off, I’m using Access 2000 and DAO. I have code that executes a simple INSERT INTO query that I call using db.Execute. This code works fine inside an mdb. However, if I compile into an mde then I get

error 5 – Invalid procedure call or argument

on this line and the record does not get inserted. However, if I change from db.Execute to DoCmd.RunSQL using the exact same SQL statement the record is inserted with no problems. Does anyone know why the DAO Execute method of the DAO database object would suddenly stop working once I compile into an MDE?

Note: I only get the error if I specify the dbFailOnError option of the .Execute method. If I leave that option off, I get no error but the record is still not inserted.

EDIT:
This line fails in the MDE (but works fine in the MDB):

App.db.Execute InsertSQL, dbFailOnError

From the immediate window with a breakpoint on the above line of code:

?InsertSQL
INSERT INTO Changes
(PropertyID, FieldID, [Which], [When], [Before], Reason, ReportChange)
VALUES (1, 2, "M", #2/19/2010 4:51:44 PM#, "Suite 2; 430 W KING ST; ABBOTTSTOWN, PA 17301-9771", "Per Owner", True)

(I have an entire class module dedicated to building and executing SQL statements, so it’s not really practical to show exactly how I built the InsertSQL string variable. However, I really don’t think that is relevant.)

This line works everywhere:

DoCmd.RunSQL InsertSQL

EDIT: App.db definition (note that there is no reference in my project to ADO, only DAO):

Public App As New clsApp

clsApp class module (relevant lines only):

Private m_objDB As Database

Public Property Get db() As Database
    Set db = m_objDB
End Property

Private Sub Class_Initialize()
    Set m_objDB = CurrentDb
End Sub

Private Sub Class_Terminate()
    Set m_objDB = Nothing
End Sub

If you are curious, I use App.db rather than CurrentDB for two main reasons: 1) slight performance gain by not having to call the CurrentDB function repeatedly (call it once then just refer to the object it returns) and 2) properties of the database object like .RecordsAffected always return relevant information. Plus, it’s faster to type. And I’m a programmer, so I’m inherently lazy.

EDIT: Let me first apologize to those who have been following this thread and trying to help me. It seems I may have left out the critical details of my problem. The App.db.Execute call takes place inside a class module (clsSQL) and it references a global variable named App which is itself an instance of a different class module (clsApp). I’m guessing the problem is that I am referring to an instance of a class module from within another class module. Can anyone confirm if calling one class module from within another is something that is supported by MDBs and not MDEs? [It is not an issue. I was way over-thinking this. See my answer for the full story.]

Answer 1

Firstly, my sincere apologies to those who tried to help me with this. As I find so frustrating when others ask questions, I left out the key piece of information because I did not think it was relevant. Here was the full initialize procedure for my clsApp class module:

Private Sub Class_Initialize()
    Application.Echo True
    m_bEcho = True

    Set m_objDB = CurrentDb
    m_sUser = GetUserName
    Set m_objStatus = New clsStatus
    m_sPgmName = Application.CurrentProject.Name
    m_sPgmName = Left(m_sPgmName, InStr(m_sPgmName, ".mdb") - 1)
End Sub

The key line is that last one. When I compiled into an “.mde”, the string “.mdb” was no longer present in the CurrentProject.Name. As a result, the call to InStr() returned 0. And 0 - 1 = -1. So I was passing a negative number as the Length parameter for the Left() function. However, the length parameter cannot be negative. It is most definitely an “Invalid procedure call or argument.”

My simple fix was to remove the “mdb” from “.mdb” and just check for the location of the “.” This also works correctly with the “.accdb” and “.accde” 2007 extensions.

Again, my apologies.