Question

How to exclude specific descendants of a node? In this direction, the expression *[not(self::nodetag)] seems just to discriminate at a child level of the node, accepting all other descedants in the returned node set. I want a expression to select all under div but those nodes that are not a, see example below. The tree structure must remain the same.

The approach poste by @Dimitri Novatchev seems to be right but not for HAP implementation:

Using this example document:

<div>
  <span>
     <a>lala</a>
  </span>
</div>

The HAP would return the following structure with his suggested expression /div/descendant::node()[not(self::a)]

<div>
  <span>
     <a>lala</a>
  </span>
</div>
<span>
     <a>lala</a>
 </span>

If there would be another tag other than a nested on span, it would also return it as a separte tree, any one know about this strange behavior? Is it a HAP bug?

Thanks

Answer 1

I want a expression to select all under div but those nodes that are
not a. The tree structure must remain the same.

Use:

/div/descendant::node()[not(self::a)]

This selects any descendant of the top element div that (the descendant) is not an a.

XSLT – based verification:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:for-each select="/div/descendant::node()[not(self::a)]">
    <xsl:value-of select="concat('&#xA;', position(), '. &quot;')"/>
    <xsl:copy-of select="."/>"
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document:

<div>
    <span>
        <a>lala</a>
    </span>
</div>

the XPath expression is evaluated and all selected nodes are output with proper formatting to make them well-visible:

1. "
    "

2. "<span>

   <a>lala</a>

</span>"

3. "
        "

4. "lala"

5. "
    "

6. "
"

As we can see, 6 nodes are selected — one span element, four whitespace-only text nodes and one non-whitespace-only text node — and none of them is an a.

Update:

In a comment the OP has clarified that he actually wants the XML document to be transformed into another, in which any a descendant of a div is omitted.

Here is one such transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="div//a"/>
</xsl:stylesheet>

When this transformation is applied on the same XML document (above), the (wwhat I guess is) wanted result is produced:

<div>
   <span/>
</div>

If we want to produce only the descendants of any div that has an a descendant, then we need almost the same transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="div[.//a]"><xsl:apply-templates/></xsl:template>
 <xsl:template match="div//a"/>
</xsl:stylesheet>

The result of this applied to the same XML document as above is:

<span/>