Question

I am still new with using XML::Twig.

From the main program I look for the elements with attribute @method="create"

In the subroutine player, I want to find the next element/sibling with attribute @method="modify".

Both of these methods fail in subroutine player with the error Can't call method "gi" on an undefined value

my $modif1=$valeur->next_sibling('[@method="modify"]')

my $modif2=$valeur->next_elt('[@method="modify"]')->parent

Example of input.xwo:

<top id="World">

  <middle id="France" method="create">
  </middle>

  <middle id="Germany" method="modify">
  </middle>

</top>

My simple code:

#!/bin/perl -w
use warnings;
use XML::Twig;

my $twig= new XML::Twig( 
  twig_handlers => {
    '[@method="create"]' => \&player
  } 
);                    

$twig->parsefile("input.xwo");
$twig->purge;  

sub player { 

  my ($twig, $valeur) = @_;                     

  my $modif1 = $valeur->next_sibling('[@method="modify"]');
  my $modif2 = $valeur->next_elt('[@method="modify"]')->parent;
  print "\nnextELT=" . $modif->gi . "\n";
}

Answer 1

Please always use strict at the top of your programs and declare variables using my at their first point of use. There is no point in both use warnings and the -w command-line option. The first is preferable.

When the twig handler for the <middle method="create"> element is called, the sibling that you require, <middle method="modify"> hasn’t been processed. It can’t be found because it isn’t yet in the XML::Twig parse tree.

You must either read the entire XML structure and process it afterwards, or write a handler for the element that encloses both the create and modify elements.

This program does the latter.

use strict;
use warnings;

use XML::Twig;

my $twig= XML::Twig->new(
  twig_handlers => {
    top => \&player
  } 
);                    

$twig->parsefile('input.xwo');
$twig->purge;  

sub player { 

  my ($twig, $valeur) = @_;                   

  my $create = $valeur->first_child('[@method="create"]');
  return unless $create;

  my $modify = $create->next_sibling('[@method="modify"]');
  return unless $modify;

  printf "\nnextELT = %s\n", $modify->gi;

  $twig->purge;
}

---

Update

This alternative reads the entire XML tree and extracts the data from it afterwards. It starts by finding all elements in the tree that have a method attribute equal to 'create', and then finds the following sibling of each of them with a method attribute of 'modify'.

use strict;
use warnings;

use XML::Twig;

my $twig= XML::Twig->new;

$twig->parsefile('input.xwo');

my @creates = $twig->get_xpath('//*[@method="create"]');

foreach my $create (@creates) {
  my $modify = $create->next_sibling('[@method="modify"]');
  next unless $modify;
  printf "\nnextELT = %s\n", $modify->gi;
}