Question

I am trying to cascade dropdowns using ASP and VB

1st drop down   --> Sex Type
                            > Male
                            > Female
2nd Drop Down   -->Status
                            > Orphan
                            > Married
                            > UnMarried
                            > Divorced
                            > Widow
                            > Special Need
                            > Normal

Now,
If Male selected from 1st drop down, then select (Orphan, Special Need, Married, UnMarried, Divorced, Widow and Normal) from 2nd Drop Down

And if Female selected from 1st drop down, then select (Orphan, Special Need and Normal) from 2nd Drop Down

I am getting data of drop dwons from database using Entities;

VB Code

context As New EGrantsModel.Entities

ddlSexType.DataSource = context.SEXTYPE
ddlSexType.DataValueField = "SEXTYPE"
ddlSexType.DataTextField = "SEXTYPE"
ddlSexType.DataBind()

ddlCitizenStatus.DataSource = context.CITIZENSTATUS
ddlCitizenStatus.DataValueField = "CITIZENSTATUSID"
ddlCitizenStatus.DataTextField = "CITIZENSTATUS"
ddlCitizenStatus.DataBind()

ASP Code

<div class="labelinput">
 <asp:Label ID="lblSexType" CssClass="lblwidth" runat="server" Text="">Sex Type</asp:Label>
 <asp:DropDownList ID="ddlSexType" runat="server"/>
   </div>

 <div class="labelinput">
   <asp:Label ID="lblCitizenStatus" CssClass="lblwidth" runat="server" Text="">Status</asp:Label>
    <asp:DropDownList ID="ddlCitizenStatus" runat="server"/>
     </div>

Can any one guide me in this regards. Thank you

Answer 1

Check this:

Public Class WebForm4
    Inherits System.Web.UI.Page

    Private Sub CitizenBind(ByVal strSexType As String)

        Dim lstCitizenStatus As New List(Of CitizenStatus)

        With lstCitizenStatus
            .Add(New CitizenStatus("1", "Orphan"))
            .Add(New CitizenStatus("2", "Married"))
            .Add(New CitizenStatus("3", "UnMarried"))
            .Add(New CitizenStatus("4", "Divorced"))
            .Add(New CitizenStatus("5", "Widow"))
            .Add(New CitizenStatus("6", "Special Need"))
            .Add(New CitizenStatus("7", "Normal"))
        End With

        Me.ddlCitizenStatus.Items.Clear()

        With Me.ddlCitizenStatus
            .DataSource = lstCitizenStatus
            .DataValueField = "CitizenStatusId"
            .DataTextField = "CitizenStatusT"
            .DataBind()
        End With

        If strSexType.Contains("F") Then

            Dim lstCitizenStatusRemove As New List(Of CitizenStatus)
            With lstCitizenStatusRemove
                .Add(New CitizenStatus("2", "Married"))
                .Add(New CitizenStatus("3", "UnMarried"))
                .Add(New CitizenStatus("4", "Divorced"))
                .Add(New CitizenStatus("5", "Widow"))
            End With

            For Each lstCS As CitizenStatus In lstCitizenStatusRemove
                Me.ddlCitizenStatus.Items.Remove(New ListItem(lstCS.CitizenStatusT.ToString(), lstCS.CitizenStatusId.ToString()))
            Next

        End If

    End Sub

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

        If Not Page.IsPostBack Then

            Dim lstSexType As New List(Of SexType)
            lstSexType.Add(New SexType("Male"))
            lstSexType.Add(New SexType("Female"))

            With Me.ddlSexType
                .DataSource = lstSexType
                .DataValueField = "SexTypeT"
                .DataTextField = "SexTypeT"
                .DataBind()
            End With

            CitizenBind("ALL")

        End If

    End Sub

    Protected Sub ddlSexType_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs) Handles ddlSexType.SelectedIndexChanged

        CitizenBind(Me.ddlSexType.SelectedValue)

    End Sub

End Class

If you have any questions about the code please let me know.