Question

I am trying to create an array of hashes with each has being an tied, ordered IxHash. When looping through my initial hash, the keys are indeed in order. However, as soon as I push them onto an array, the ordering disappears. I know this is my poor knowledge of what is happening with the hash when it is pushed on the array, but if somebody could enlighten me, it would be much appreciated.

#! /usr/bin/perl -w

use strict;
use Data::Dumper;
use Tie::IxHash;

my @portinfo;

tie (my %portconfig, 'Tie::IxHash',
      'name' => [ 'Name', 'whatever' ],
      'port' => [ 'Port', '12345' ],
      'secure' => [ 'Secure', 'N' ]
      );

print "Dump of hash\n";
print Dumper(%portconfig);

print "\nDump of array\n";
push @portinfo, {%portconfig}; 
print Dumper(@portinfo);

The output of this :-

Dump of hash
$VAR1 = 'name';
$VAR2 = [
          'Name',
          'whatever'
        ];
$VAR3 = 'port';
$VAR4 = [
          'Port',
          '12345'
        ];
$VAR5 = 'secure';
$VAR6 = [
          'Secure',
          'N'
        ];

Dump of array
$VAR1 = {
          'secure' => [
                        'Secure',
                        'N'
                      ],
          'name' => [
                      'Name',
                      'whatever'
                    ],
          'port' => [
                      'Port',
                      '12345'
                    ]
        };

Answer 1

Your code:

push @portinfo, {%portconfig}; 
print Dumper(@portinfo);

takes the tied hash %portconfig and places its contents into a new anonymous hash which is then pushed into @portinfo. Thus, you have an anonymous, non-ordered hash in your array.

What you probably mean to do is

push @portinfo, \%portconfig; 
print Dumper(@portinfo);

This pushes a reference to %portconfig into @portinfo, thereby retaining your required ordering.

Thus:

#! /usr/bin/perl -w

use strict;
use Data::Dumper;
use Tie::IxHash;

my @portinfo;

tie (my %portconfig, 'Tie::IxHash',
      'name' => [ 'Name', 'whatever' ],
      'port' => [ 'Port', '12345' ],
      'secure' => [ 'Secure', 'N' ]
      );

print "Dump of hash\n";
print Dumper(%portconfig);

print "\nDump of array\n";
push @portinfo, \%portconfig; 
print Dumper(@portinfo);

Gives

C:\demos>perl demo.pl
Dump of hash
$VAR1 = 'name';
$VAR2 = [
          'Name',
          'whatever'
        ];
$VAR3 = 'port';
$VAR4 = [
          'Port',
          '12345'
        ];
$VAR5 = 'secure';
$VAR6 = [
          'Secure',
          'N'
        ];

Dump of array
$VAR1 = {
          'name' => [
                      'Name',
                      'whatever'
                    ],
          'port' => [
                      'Port',
                      '12345'
                    ],
          'secure' => [
                        'Secure',
                        'N'
                      ]
        };