Question

I am trying to do a binding as with following data formats:

Public Structure ItemBase
    Property ID As String
    Property Description As String
End Structure

Namespace Classes
    Public Class StockEntityClass
        Implements INotifyPropertyChanged  
#Region "Property Variables"
        Property ID As String
        Property Namee As String
        Property Units As String
        Property ContactID As String
        Property SetCount As Integer
        Property VatOnMargin As Boolean
        Property Vat As Double
        Property Code As String
        Property _ContactNamee As String
#End Region

        Public Sub New()
            _IDValue = Now.ToString
            _NameeValue = ""
            _UnitsValue = "Pcs"
            _ContactIDValue = ""
            _SetCountValue = 0
            _VatOnMarginValue = False
            _VatValue = 14.5
            _CodeValue = ""
            _ContactNamee = ""
        End Sub    
    End Class
End Namespace

In my wpf xaml window which is DataContext to Stock Entity variable, I have a combo box that is bound to BindingList(of ItemBase) and the user will select an Item and that ItemID as to get assosiated to StockEntity.ContactID.

Following is the xaml code:

<ComboBox Name="VendorsComboBox" Grid.Row="2" Grid.Column="1" VerticalAlignment="Center" DisplayMemberPath="Description" SelectedItem="{Binding Path=CustomerID}"/>

Following is Binding Code:

Dim Stock As Classes.StockEntityClass
VendorsComboBox.ItemsSource = Contacts.DBAccessFunctions.Get_ContactsByType_BaseList(DataSource, "Vendor")
        StockEntityStack.DataContext = Stock

Where StockEntityStack contains the UI part which is datacontext bind to stock variable.
Could you please tell me how to write the xaml databound to it.

Answer 1

Try something like that:

MainWindow (XAML file):

  <Window x:Class="MainWindow"
        xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
        xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
        Title="MainWindow" Height="350" Width="525">
        <StackPanel>
            <ComboBox ItemsSource="{Binding MySource}" 
                      SelectedValue="{Binding ContactID}"
                      DisplayMemberPath="Description"
                      SelectedValuePath="ID"
                      Width="180" Height="25"
                      />

            <StackPanel Orientation="Horizontal" Margin="10" >
                <TextBlock Text="Selected ID:" />
                <TextBlock Text="{Binding ContactID}" />
            </StackPanel>
        </StackPanel>
    </Window>

MainWindow (code-behind file):

Class MainWindow 
    Public Sub New()
        InitializeComponent()
        Me.DataContext = New MainViewModel()
    End Sub
End Class

MainViewModel file:

   Imports System.ComponentModel

Public Class MainViewModel
    Implements INotifyPropertyChanged

#Region "Fields"
    Private _selectedContactID As String = String.Empty
#End Region


#Region "Property Variables"
    Property MySource As List(Of ItemBase) = New List(Of ItemBase)
    Public Property ContactID As String
        Get
            Return _selectedContactID
        End Get
        Set(ByVal value As String)
            _selectedContactID = value
            OnPropertyChanged("ContactID")
        End Set
    End Property
#End Region

    Public Sub New()
        MySource.Add(New ItemBase(1, "test1"))
        MySource.Add(New ItemBase(2, "test2"))
        MySource.Add(New ItemBase(3, "test3"))
        MySource.Add(New ItemBase(4, "test4"))
        MySource.Add(New ItemBase(5, "test5"))
    End Sub

    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged

    Protected Sub OnPropertyChanged(ByVal propertyName As String)
        RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName))
    End Sub

End Class


Public Structure ItemBase
    Public Sub New( _
       ByVal _id As String,
       ByVal _description As String
       )
        ID = _id
        Description = _description
    End Sub
    Property ID As String
    Property Description As String
End Structure