Question

I am using a function to update my text fields on the stage:

private function updateFields(rootContainer:DisplayObjectContainer):void
{
    for(var i=0; i < rootContainer.numChildren; i++) {
        var item:* = rootContainer.getChildAt(i);
        try {
            updateFields(item);
        } catch (e:Error) {
            trace(e.toString());
        }
        if (item.toString() == '[object TextField]') {
            trace(item.name);
        }
    }
}

It finds half of the text fields placed on stage. Why is this? Drives me crazy.

Answer 1

This works for me.

private function updateFields(rootContainer:DisplayObjectContainer):void
{
    for (var i:uint = 0, n:uint = rootContainer.numChildren; i < n; ++i) {
        var item:DisplayObject = rootContainer.getChildAt(i);
        if (item is DisplayObjectContainer) {
            updateFields(DisplayObjectContainer(item));
        } else if (item is TextField) {
            trace(item.name);
        }
    }
}

Edit: Fixed DisplayObjectContainer casting