Question

I am using XSLT 1.0 and I’m looking to divide a xml document of for example related people in to families. The definition of family being one parent and its children.

So this:

<person name =”A”>
   <person name =”B”>
      <person name =”D” />
      <person name =”E” />
   </person>
   <person name=”C”>
      <person name =”F” />
      <person name =”G” />
      <person name =”H” />
   </person>
</person>

Will result in:

<family id =”1”>
   <person name =”A”>
      <person name =”B”/>
      <person name=”C”/>
   </person>
</family>

<family id =”2”>
   <person name =”B”>
      <person name =”D” />
      <person name =”E” />
   </person>
</family>


<family id =”3”>
   <person name=”C”>
      <person name =”F”/>
      <person name =”G”/>
      <person name =”H”/>
   </person>
</family>

How can I do this in a simple way?

Answer 1

One way is to firstly look for all person elements that have other person elements as children

<xsl:apply-templates select="//person[person]"/>

Then, for each such person element, you would copy the element, and its immediate children only

 <xsl:copy>
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates select="person" mode="child"/>
 </xsl:copy>

Also, to get the family id, you could count all preceding person elements, and ancestors

<family id="{count(preceding::person[person]) + count(ancestor-or-self::person)}">

The “child” template would just copy the person and its attributes, but no children.

Here is the full XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
       <families>
          <xsl:apply-templates select="//person[person]"/>
       </families>
   </xsl:template>

   <xsl:template match="person[person]">
      <family id="{count(preceding::person[person]) + count(ancestor-or-self::person)}">
         <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates select="person" mode="child"/>
         </xsl:copy>
      </family>
   </xsl:template>

   <xsl:template match="person" mode="child">
      <xsl:copy>
         <xsl:copy-of select="@*"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

When applied to your sample XML, the following is output

<families>
   <family id="1">
      <person name="A">
         <person>B</person>
         <person>C</person>
      </person>
   </family>
   <family id="2">
      <person name="B">
         <person>D</person>
         <person>E</person>
      </person>
   </family>
   <family id="3">
      <person name="C">
         <person>F</person>
         <person>G</person>
         <person>H</person>
      </person>
   </family>
</families>