Question

I am writing a simple Groovy application that needs to do some logging. The actual properties of how things are logged will depend on the particular environment. For instance, while developing I just want to log to the console, in test and production I may want to write to a file and in production I may want to send email for the most severe events.

Right now what I am doing looks like this:

import org.apache.log4j.Logger
import org.apache.log4j.PropertyConfigurator

class BaseClass {
    protected config

    static Logger logger = Logger.getLogger(BaseClient.class)

    def BaseClass(env) {
        def configFilePath = // whatever

        config = new JsonSlurper().parseText(configFile.text)[options.env]

        def logConfigFilePath = ['somelogdir', config.log_file].join(File.separator)
        PropertyConfigurator.configure(logConfigFilePath)
    }
}

and then all my classes that need to do logging inherit from BaseClass.

In this way, I can specify a different filename for each environment, and I get to read the logging configuratio from there. But it seems a lot of boilerplate, and forces me to use a hierarchy that may not be ideal.

On the other hand, here I see that I can obtain a logger with a simple annotation.

Is there a way to get different loggers depending on the environment – which may be set at runtime?

Answer 1

Building on tim_yates’s answer, use a groovy file to configure log4j. For example:

// log4j.groovy
log4j {
    rootLogger="DEBUG, A1"
    appender.A1 = "org.apache.log4j.ConsoleAppender"
    appender.'A1.layout' = "org.apache.log4j.PatternLayout"

    if (System.properties['env'] == 'prod') {
        appender.'A1.layout.ConversionPattern'="prod %-4r [%t] %-5p %c %x - %m%n"
   } else {
        appender.'A1.layout.ConversionPattern'="dev %-4r [%t] %-5p %c %x - %m%n"
   }
}

Then make your script use it:

@GrabConfig(systemClassLoader=true)
@Grab(group='log4j', module='log4j', version='1.2.17')

import groovy.util.logging.Log4j
import org.apache.log4j.PropertyConfigurator

@Log4j
class Test {
    def dosome() {
        log.info('Logging!')
    }

    static main( args ) {
        def config = new ConfigSlurper().parse(new File('log4j.groovy').toURL())
        PropertyConfigurator.configure(config.toProperties())

        new Test().dosome()
    }
}

And finally, launch your program with the environment in a system property:

groovy -Denv=prod Test.groovy