Question

I have a project where the data is arriving from the network (not a database) and has it’s own parsing peculiarities.

The parsing process stores the data in a array of objects of a class that is full of Public Property.

This class and it’s array is used as an object data source to a BindingSource that shows the values as a nice table in a DataGridView on the screen.

Now I need to save this data to disk (and be able in a later moment to retrieve it back to be sent back to the network).

I’ve worked before with DataSet saving to XML and it’s a breeze to implement, but this one is puzzling me.

All this information is already in the code, so I don’t think I should be typing line by line, each one of the properties to be able to save it.
I’ve been trying without success some way to get the data out of the binder to a new DataSet so I can use the XML method, or some way to get from the binder to disk, or even directly access the DataSource objects.

I really don’t care if even it’s readable as a plain text in disk, as long as I can read it back to the DataSource objects at a later point.

any ideas how to accomplish that?

Answer 1

Why not just use a XmlSerializer to save your object?

---

Example:

Class MyData
    Public Property Data1 As String
    Public Property Data2 As Int32
    Public Property Data3 As String()
End Class

Sub Main

    Dim d = New MyData() With { _
        .Data1 = "FooBar", _
        .Data2 = 1337, _
        .Data3 = new String(){"Foo", "Bar"} _
    }

    Dim serializer = new System.Xml.Serialization.XmlSerializer(gettype(MyData))

    '' Saving an object
    Using fs = new System.IO.FileStream("c:\users\username\mydata.xml", System.IO.FileMode.Create)
        serializer.Serialize(fs, d)
    End Using

    '' Loading the saved data to a new object        
     Using fs = new System.IO.FileStream("c:\users\username\mydata.xml", System.IO.FileMode.Open)
        Dim new_one = CType(serializer.Deserialize(fs), MyData)
        '' Do something
    End Using

End Sub

Resulting file content:

<?xml version="1.0"?>
<MyData xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
  <Data1>FooBar</Data1>
  <Data2>1337</Data2>
  <Data3>
    <string>Foo</string>
    <string>Bar</string>
  </Data3>
</MyData>