Question

I have a VBScript that takes some arguments (name, email, etc) and I created a HTML form.

When the user types the data, I want to execute the VBScript and pass the form data as parameters.

The question is how do I run a VBScript from an HTML form(there is no Server so the client executes the HTML and runs the VBscript on their machine).

The VBScript is an external file. Lets call it myScript.vbs

Answer 1

As a matter of coincidence i just yesterday published a question how to do this in Ruby and gave a vbscript script as sample, so here you have it. But in fact it is best the other way round, you best start the browser from your script.

Set web = CreateObject("InternetExplorer.Application") 
If web Is Nothing Then 
  msgbox("Error while loading Internet Explorer") 
  Wscript.Quit 
Else 
  with web 
    .Width = 300 
    .Height = 175 
    .Offline = True 
    .AddressBar = False 
    .MenuBar = False 
    .StatusBar = False 
    .Silent = True 
    .ToolBar = False 
    .Navigate "about:blank" 
    .Visible = True 
  end with 
End If 

'Wait for the browser to navigate to nowhere 
Do While web.Busy 
  Wscript.Sleep 100 
Loop 

'Wait for a good reference to the browser document 
Set doc = Nothing 
Do Until Not doc Is Nothing 
  Wscript.Sleep 100 
  Set doc = web.Document 
Loop 

'Write the HTML form 
doc.Write "Give me a name<br><form><input type=text name=name ><input type=button name=submit id=submit value='OK' onclick='javascript:submit.value=""Done""'></form>" 
Set oDoc = web.Document 
Do Until oDoc.Forms(0).elements("submit").Value <> "OK" 
  Wscript.Sleep 100 
  If web Is Nothing or Err.Number <> 0 Then 
    msgbox "Window closed" 
    Wscript.Quit 
  End If 
Loop 
name = oDoc.Forms(0).elements("name").value 
oDoc.close 
set oDoc = nothing 
web.quit 
set web = nothing 
Wscript.echo "Hello " & name