Question

I have an excel file with 85,000 rows and I need to extract just the cell comments, but it’s currently too large, so I am wondering if I can write some VB (never done it before) or a macro or something that goes through each row, looks to see if any columns have a cell comment and if not, then deletes the row.

Any hints on how to achieve this would be appreciated! I have a programming background (and did some VB2-6 many, many years ago but have never programmed for Excel)

Answer 1

Make sure your sheet is active, replace “12” with the number of columns you are concerned with for numColumns. Some On Error trickery is needed in HasComment() because Comment.Text errors if you try to check its value when it doesn’t exist:

Sub RemoveRowsWithoutComments()
Dim rngAll As Range, rng As Range
Dim numColumns As Integer, colCntr As Integer, rowCntr As Long
Dim rowHasComment As Boolean

'set YOUR number of columns
numColumns = 12

Set rngAll = Range("A1", Range("A1").End(xlDown))

rowCntr = rngAll.Count - 1

'need to work backwards because deleting rows messes up forward iteration
Do Until rowCntr = -1

'work with current row (descending)
Set rng = Range("A1").Offset(rowCntr, 0)

rowHasComment = False

    For colCntr = 0 To numColumns

        If HasComment(rng.Offset(0, colCntr)) Then
            rowHasComment = True
            Exit For
        End If

    Next colCntr

    If Not rowHasComment Then rng.Rows.EntireRow.Delete

'decrement
rowCntr = rowCntr - 1
Loop
End Sub

Function HasComment(rng As Range) As Boolean
On Error GoTo NoComment

    If rng.Comment.Text <> "" Then
        HasComment = True
        Exit Function
    End If

NoComment:
    HasComment = False

End Function