Question

I have saved a really big QueryString into a MS SQL column the string looks something like this:

&s1=Toledo,OH&s2=Chicago,IL&s3=Madison,WI.....and so on...

I would like to be able to do/have something like this in ASP-Classic:

Dim s1,s2,s3,s4....and son on...

s1="Toledo,OH"
s2="Chicago,IL"
s3="Madison,WI"
.....and son on.....

I would like to be able to call them like I would a QueryString for example a QueryString call would be Request.QueryString(“s1”) or I can use Do and loop all of the Request.QueryString(“s” & i) until the query =”” then I would Exit the Do.

But how would I make all of this happen if I saved it the query.string into a MS DB Column?

Please help,

Thank you…

I keep getting this error: Variable is undefined: ‘s1’, what am I doing wrong here ?

    Function qq(s)
      qq = """" & s & """"
    End Function ' qq


    Dim sInp    : sInp        = objRSConnSAVE("QSTRING")
      Dim dicData : Set dicData = Server.CreateObject("Scripting.Dictionary")
      Dim oRE     : Set oRE     = New RegExp
      oRE.Global  = True
      oRE.Pattern = "&([^=]+)=([^&]*)"
      Dim oMTS    : Set oMTS    = oRE.Execute(sInp)
      Dim oMT
      For Each oMT In oMTS
          dicData(oMT.SubMatches(0)) = oMT.SubMatches(1)
      Next

      Dim sKey, sValue
        For Each sKey In dicData.Keys
          sValue = dicData(sKey)
         '''// Response.write qq(sKey) & "=>" & qq(sValue)

      Next

    Response.write "TEST" & s1
   '// I even tried Response.write "TEST" & s(1) same error, how do I call it ?

Answer 1

Use a RegExp (instead of Split) and a dictionary (instead of a bunch of scalar variables):

  Dim sInp    : sInp        = "&s1=Toledo,OH&s2=Chicago,IL&s3=Madison,WI"
  Dim dicData : Set dicData = CreateObject("Scripting.Dictionary")
  Dim oRE     : Set oRE     = New RegExp
  oRE.Global  = True
  oRE.Pattern = "&([^=]+)=([^&]*)"
  Dim oMTS    : Set oMTS    = oRE.Execute(sInp)
  Dim oMT
  For Each oMT In oMTS
      dicData(oMT.SubMatches(0)) = oMT.SubMatches(1)
  Next
  Dim sKey, sValue
  For Each sKey In dicData.Keys
      sValue = dicData(sKey)
      WScript.Echo qq(sKey), "=>", qq(sValue)
  Next

output:

"s1" => "Toledo,OH"
"s2" => "Chicago,IL"
"s3" => "Madison,WI"

UPDATE:

qq() is a function to double quote a string:

Function qq(s)
  qq = """" & s & """"
End Function ' qq

UPDATE II:

Use dicData("s2") to get Chicago,IL