Question

I have the following Adobe Flash (ActionScript 3.0) movie:

When a button is pressed I want to play frame 17 to 24, and after this, I want to go back and play frame 10 to 16 in the same animation. I’ve tried something like this but unfortunately doesn’t works:

button.addEventListener(MouseEvent.CLICK, buttonClick);

function buttonClick(event:MouseEvent):void{
        gotoAndPlay(17);
        gotoAndPlay(10);
}

In other short words: after gotoAndPlay(17); I want to gotoAndPlay(10);

Thanks for your attention!

Answer 1

Try this:

stop();


// Properties.
var queue:Array = [];
var currentBlock:Point;


// Queue a section of timeline to play.
function queueBlock(start:int, end:int):void
{
    queue.push(new Point(start, end));
}


addEventListener(Event.ENTER_FRAME, enterFrame);
function enterFrame(e:Event):void
{
    if(!currentBlock)
    {
        if(queue.length > 0)
        {
            // Select and remove first block to play.
            currentBlock = queue[0];
            queue.splice(0, 1);

            gotoAndPlay(currentBlock.x);
        }
    }
    else
    {
        play();

        if(currentBlock.y == currentFrame)
        {
            // Got to the end of the block, end it.
            currentBlock = null;
            stop();
        }
    }
}

Which will let you do this:

// Demo:
queueBlock(17, 24);
queueBlock(10, 16);