Question

I like to capture all global variables from an external Perl script with Perl. Currently I am hanging around the type detection.

How to determine the correct data type (”, ‘SCALAR’, ‘HASH’, ‘ARRAY’, ‘CODE’)?

Parser script:

my %allVariables = ();
{
     do "scriptToBeParsed.pl";
     foreach my $sym ( keys %main:: ) {
         # Get all normal variables and scalar/hash/array references:
        if ( ref( *{"$sym"} ) =~ m/^(?:|SCALAR|HASH|ARRAY)$/ ) {
            $allVariables{"$sym"} = *{"$sym"};
        }
    }
}

Script to be parsed:

$someVariable1 = 'Yes, I like to be captured';
$otherVariable2 = \'And I also want to be captured';
%anotherVariable3 = ( 'Capture' => 'me' );
@lameVariable4 = ( 'Capture', 'me' );
$fooVariable5 = { 'Capture' => 'me' };
$barVariable6 = [ 'Capture', 'me' ];
$subVariable7 = sub { return "Don't capture me!" };
sub dontCaptureMe { return "Don't capture me!" }

In my example ref( *{"$sym"} ) returns always ‘GLOB’ (of course).

Answer 1

Another approach would be to use the has-like access of the typeglob, which is explained in Chapter 8 of brian d foy’s Mastering Perl on page 131f.

package test;
no strict;
no warnings; 

$someVariable1 = 'Yes, I like to be captured';
$otherVariable2 = \'And I also want to be captured';
%anotherVariable3 = ( 'Capture' => 'me' );
@lameVariable4 = ( 'Capture', 'me' );
$fooVariable5 = { 'Capture' => 'me' };
$barVariable6 = [ 'Capture', 'me' ];
$subVariable7 = sub { return "Don't capture me!" };
sub dontCaptureMe { return "Don't capture me!" }

say $dontCaptureMe;
my %allVariables = ();
{
  do "scriptToBecomeParsed.pl";
  foreach my $sym ( keys %test:: ) {
    for (qw( SCALAR HASH ARRAY CODE IO)) {
      if (*{"$sym"}{$_}) {
        $allVariables{$_}->{"$sym"} = *{"$sym"}{$_};
      }
    }
  }
}

print Data::Dumper::Dumper \%allVariables;

This will produce the following output:

$VAR1 = {
          'CODE' => {
                      'dontCaptureMe' => sub { "DUMMY" }
                    },
          'ARRAY' => {
                       'lameVariable4' => [
                                            'Capture',
                                            'me'
                                          ]
                     },
          'HASH' => {
                      'anotherVariable3' => {
                                              'Capture' => 'me'
                                            }
                    },
          'SCALAR' => {
                        'someVariable1' => \'Yes, I like to be captured',
                        '__ANON__' => \undef,
                        'subVariable7' => \sub { "DUMMY" },
                        'dontCaptureMe' => \undef,
                        'otherVariable2' => \\'And I also want to be captured',
                        'BEGIN' => \undef,
                        'barVariable6' => \[
                                              'Capture',
                                              'me'
                                            ],
                        'anotherVariable3' => \undef,
                        'lameVariable4' => \undef,
                        'fooVariable5' => \{
                                              'Capture' => 'me'
                                            }
                      }
        };