Question

I need to transform input paramater string like “1-410000 54-420987 63-32000” into the structure (like below) inside xslt to use its data later in xslt:

<config:categories>
  <category>
    <value>410000</value>
    <label>1</label>
  </category>
  <category>
    <value>420987</value>
    <label>54</label>
  </category>
  <category>
    <value>32000</value>
    <label>63</label>
  </category>
</config:categories>

P.S.
Are there any other options to parse string like “1-410000 54-420987 63-32000” in order to use its data in xslt to extract the right part (after the ‘-‘) if the left part is found in input document?

Answer 1

This transformation:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:config="some:config" exclude-result-prefixes="config">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pData" select="'1-410000 54-420987 63-32000'"/>

 <xsl:template match="/*">
     <config:categories>
       <xsl:call-template name="gen"/>
     </config:categories>
 </xsl:template>

 <xsl:template name="gen">
  <xsl:param name="pGen" select="$pData"/>

  <xsl:if test="$pGen">
   <xsl:variable name="vChunk" select=
    "substring-before(concat($pGen, ' '), ' ')"/>
      <category>
        <value><xsl:value-of select="substring-after($vChunk,'-')"/></value>
        <label><xsl:value-of select="substring-before($vChunk,'-')"/></label>
      </category>
      <xsl:call-template name="gen">
       <xsl:with-param name="pGen" select="substring-after($pGen, ' ')"/>
      </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

when applied on any XML document (not used), produces the wanted, correct result:

<config:categories xmlns:config="some:config">
   <category>
      <value>410000</value>
      <label>1</label>
   </category>
   <category>
      <value>420987</value>
      <label>54</label>
   </category>
   <category>
      <value>32000</value>
      <label>63</label>
   </category>
</config:categories>

Explanation:

Proper use of substring-before() and substring-after() plus recursion.