Question

I want each (small) file specified with ARGV read in its own array. If I don’t test $ARGV, <> will slurp all files in a single table. Is there a better/shorter/simpler way of doing it?

# invocation: ./prog.pl *.txt

@table = ();
$current = "";
while (<>)
{
  if ($ARGV ne $current)
  {
    @ar = ();
    $current = $ARGV;
    if ($current)
    {
      push @table, \@ar;
    }
  }
  push @ar;
}

Answer 1

Please always use strict and use warnings at the top of your programs, and declare variables close to their first point of use using my.

It is simplest to test end of file on the ARGV filehandle to determine when a new file is about to be opened.

This code uses a state variable $eof to record whether the previous file has been completely read to avoid unnecessarily adding a new element to the @table array when the end of the @ARGV list is reached.

use strict;
use warnings;

my @table;
my $eof = 1;

while (<>) {
  chomp;
  push @table, [] if $eof;
  push @{$table[-1]}, $_;
  $eof = eof;
}

---

@Alan Haggai Alavi’s idea of incrementing an index at end of file instead of setting a flag is far better as it avoids the need to explicitly create an empty array at the start of each file.

Here is my take on his solution, but it is completely dependent on Alan’s post and he should gete the credit for it.

use strict;
use warnings;

my @table;
my $index = 0;

while (<>) {
  chomp;
  push @{$table[$index]}, $_;
  $index++ if eof;
}