Question

I was thinking I could do this on my own but I need some help.

I need to paste a list of email addresses from a local bands mail list into a textarea and process them my Perl script.

The emails are all in a single column; delimited by newlines:

[e-mail]
[e-mail]
[e-mail]
[e-mail]
[e-mail]

I would like to obviously get rid of any whitespace:

$emailgoodintheory =~ s/\s//ig; 

and I am running them through basic validation:

if (Email::Valid->address($emailgoodintheory)) { #yada

I have tried all kinds of ways to get the list into an array.

my $toarray = CGI::param('toarray');
my @toarraya = split /\r?\n/, $toarray;
foreach my $address(@toarraya) {
    print qq~ $address[$arrcnt]<br /> ~:
    $arrcnt++;
}

Above is just to test to see if I was successful. I have no need to print them.
It just loops through, grabs the schedules .txt file and sends each member the band schedule. All that other stuff works but I cannot get the textarea into an array!

So, as you can see, I am pretty lost.

Thank you sir(s), may I have another quick lesson?

Answer 1

You seem a bit new to Perl, so I will give you a thorough explanation why your code is bad and how you can improve it:

1 Naming conventions:

I see that this seems to be symbolic code, but $emailgoodintheory is far less readable than $emailGoodInTheory or $email_good_in_theory. Pick any scheme and stick to it, just don’t write all lowercase.

I suppose that $emailgoodintheory holds a single email address. Then applying the regex s/\s//g or the transliteration tr/\s// will be enough; space characters are not case sensitive.

Using a module to validate adresses is a very good idea. 🙂

2 Perl Data Types

Perl has three man types of variables:

Scalars can hold strings, numbers or references. They are denoted by the $ sigil.

Arrays can hold an ordered sequence of Scalars. They are denoted by the @ sigil.

Hashes can hold an unordered set of Scalars. Some people tend to know them as dicitonaries. All keys and all values must be Scalars. Hashes are denoted by the % sigil.

A word on context: When getting a value/element from a hash/array, you have to change the sigil to the data type you want. Usually, we only recover one value (which always is a scalar), so you write $array[$i] or $hash{$key}. This does not follow any references so

 my $arrayref = [1, 2, 3];
 my @array = ($arrayref);
 print @array[0]; 

will not print 123, but ARRAY(0xABCDEF) and give you a warning.

3 Loops in Perl:

Your loop syntax is very weird! You can use C-style loops:

for (my $i = 0; $i < @array; $i++)

where @array gives the length of the array, because we have a scalar context. You could also give $i the range of all possible indices in your array:

for my $i (0 .. $#array)

where .. is the range operator (in list context) and $#array gives the highest available index of our array. We can also use a foreach-loop:

foreach my $element (@array)

Note that in Perl, the keywords for and foreach are interchangeable.

4 What your loop does:

foreach my $address(@toarraya) {
   print qq~ $address[$arrcnt]<br /> ~:
   $arrcnt++;
}

Here you put each element of @toarraya into the scalar $address. Then you try to use it as an array (wrong!) and get the index $arrcnt out of it. This does not work; I hope your program died.

You can use every loop type given above (you don’t need to count manually), but the standard foreach loop will suit you best:

foreach my $address (@toarraya){
   print "$address<br/>\n";
}

A note on quoting syntax: while qq~ quoted ~ is absolutely legal, this is the most obfuscated code I have seen today. The standard quote " would suffice, and when using qq, try to use some sort of parenthesis (({[<|) as delimiter.

5 complete code:

I assume you wanted to write this:

my @addressList = split /\r?\n/, CGI::param('toarray');

foreach my $address (@addressList) {

   # eliminate white spaces
   $address =~ s/\s//g;

   # Test for validity
   unless (Email::Valid->address($address)) {
      # complain, die, you decide
      # I recommend:
      print "<strong>Invalid address »$address«</strong><br/>";
      next;
   }

   print "$address<br/>\n";
   # send that email
}

And never forget to use strict; use warnings; and possibly use utf8.