Question

I’m just starting with Groovy. I’m sure that I’m missing something stupid. Can someone tell me why this code fails in the groovy console? It thinks that there are only 14 words and 1 line in the input string.

def input = """
line1: 50 65 42
line2: 123 456 352 753 1825
line3: 10 25 20 48 107
"""

words = input.split(/ /)
lines = input.split(/^/)
assert words.size() == 16
assert lines.size() == 3

Answer 1

In the case of the first assert, the error message can hint to where the problem is at:

Assertion failed: 

assert words.size() == 16
       |     |      |
       |     14     false
       [
       line1:, 50, 65, 42
       line2:, 123, 456, 352, 753, 1825
       line3:, 10, 25, 20, 48, 107
       ]

There are some commas missing there and the way the words value is printed seems wrong. What is happening is that input.split(/ /) is splitting the input string by spaces, but, as it also contains newlines, some words are not split, e.g., '42\nline2:'.

To see this more clearly, we can use the inspect method, which gives us a string with the literal form of an object:

println input.inspect()
// --> '\nline1: 50 65 42\nline2: 123 456 352 753 1825\nline3: 10 25 20 48 107\n'

println input.split(/ /).inspect()
// --> ['\nline1:', '50', '65', '42\nline2:', '123', '456', '352', '753', '1825\nline3:', '10', '25', '20', '48', '107\n']

To split a word by whitespace Groovy adds a convenience non-parametrized split method:

def words = input.split()
assert words.size() == 16
println words.inspect()
// --> ['line1:', '50', '65', '42', 'line2:', '123', '456', '352', '753', '1825', 'line3:', '10', '25', '20', '48', '107']

And to get the lines of a string you can use readLines.

def lines = input.readLines()
println lines.inspect()
// --> ['', 'line1: 50 65 42', 'line2: 123 456 352 753 1825', 'line3: 10 25 20 48 107']

Notice, however that readLines will return four elements, as there is a first empty line (i don’t know why it ignores the last empty line though), so the assert lines.size() == 3 will still fail.

You can filter-out those empty lines using Collection#findAll() on the resulting list, or calling String#findAll(Pattern) directly on the input string:

def lines = input.readLines().findAll()
assert lines.size() == 3

def lines2 = input.findAll(/\S+/)
assert lines2.size() == 3

assert lines == lines2