Question

I’m new with backbone and Rails. When I return to the index view in the last line, the index view is not updated with the new value created.

class App.Views.ProfilesIndex extends Backbone.View
template: JST['profiles/index']

initialize: ->
    @collection.on('reset', @render, this)

render: ->
    $(@el).html(@template(profiles: @collection))
    this

And this is my code for the new view

class App.Views.ProfilesNew extends Backbone.View
template: JST['profiles/new']

initialize: ->
    @collection = new App.Collections.Profiles()

events: ->
    'submit #new_profile': 'createProfile'

render: ->
    $(@el).html(@template())
    this

createProfile: (event) ->
    event.preventDefault()
    attributes = name: $('#new_profile_name').val()
    @collection.create attributes,
        success: -> Backbone.history.navigate("/profiles", {trigger: true})

So, I need to update the collection when the new element is created and returned to index view.

Router

class App.Routers.Profiles extends Backbone.Router
routes:
    'profiles': 'index'
    'profiles/new': 'new'

initialize: ->
    @collection = new App.Collections.Profiles()
    @collection.fetch()

index: ->
    view = new App.Views.ProfilesIndex(collection: @collection)
    $('#container').html(view.render().el)
    
new: ->
    view = new App.Views.ProfilesNew()
    $('#container').html(view.render().el)

Answer 1

You have two distinct App.Collections.Profiles collections. Your router has one:

class App.Routers.Profiles extends Backbone.Router
    #...
    initialize: ->
        @collection = new App.Collections.Profiles()

And your ProfilesNew view has its own:

class App.Views.ProfilesNew extends Backbone.View
    #...
    initialize: ->
        @collection = new App.Collections.Profiles()

Your createProfile method adds the new profile to the @collection in the ProfilesNew view and then the router hands its @collection to the ProfilesIndex view:

index: ->
    view = new App.Views.ProfilesIndex(collection: @collection)
    $('#container').html(view.render().el)

I think you should have just one collection: the one in the router. Then hand that to the ProfilesNew view:

new: ->
    view = new App.Views.ProfilesNew(collection: @collection)
    $('#container').html(view.render().el)

and remove the initialize method from ProfilesNew. A view’s initialize will copy the collection option to @collection for you:

There are several special options that, if passed, will be attached directly to the view: model, collection, el, id, className, tagName and attributes.

Emphasis mine.