Question

I’m trying to compute duration in awk having start and end date. Here is my function

function computeDuration(start, end) {
    sub(/T/, " ", start);
    sub(/T/, " ", end);
    print start;
    print end;
    cmd="date --date=\"$start\" +%s";
    cmd | getline startDate;
    cmd="date --date=\"$end\" +%s";
    cmd | getline endDate;
    print startDate;
    print endDate;
    return endDate-startDate;
}

My output is:

2012-7-16 13:20
2012-7-16 13:30
1342389600
1342389600

Can anybody explain how it is possible that two different dates result in the same +%s result?

Answer 1

It is the the cmd variables that fail.

awk 'function computeDuration(start, end) {
print start;
print end;
cmd="date --date=\"start\" +%s";print cmd;
cmd | getline startDate;
cmd="date --date=\"end\" +%s";print cmd;
cmd | getline endDate;
print startDate;
print endDate;
return endDate-startDate;
} BEGIN {computeDuration("2012-7-16 13:20","2012-7-16 13:30")}'

OUTPUT:
2012-7-16 13:20
2012-7-16 13:30
date --date="$start" +%s
date --date="$end" +%s
1342389600
1342389600

The $ symbol shouldn’t be there and you need extra quotation marks surrounding the variables

awk 'function computeDuration(start, end) {
print start;
print end;
cmd="date --date=\""start"\" +%s";print cmd;
cmd | getline startDate;
cmd="date --date=\""end"\" +%s";print cmd;
cmd | getline endDate;
print startDate;
print endDate;
return endDate-startDate;
} BEGIN {print computeDuration("2012-7-16 13:20","2012-7-16 13:30")}'

OUTPUT:
2012-7-16 13:20
2012-7-16 13:30
date --date="2012-7-16 13:20" +%s
date --date="2012-7-16 13:30" +%s
1342437600
1342438200