Question

I’m trying to sort values from a XML file in a HTML tag with , my code looks like this:

<option value="{id/value}">

    <xsl:value-of select="short_name/value" >
    <xsl:sort select="short_name/value"/>
    </xsl:value-of>

</option>

Where do I have to put the tag here? I only get an java.io.IOException: com.caucho.xsl.XslParseException.
The should just be ordered by the shortname/value from the XML file.

Answer 1

The xsl:value-of is not allowed to contain any next xsl elements, like xsl:sort. The sort command only really applies either for xsl:for-each or xsl:apply-templates.

<xsl:for-each select="short_name/value" > 
   <xsl:sort select="."/> 
   <xsl:value-of select="." />
</xsl:for-each> 

Or, as it is preferable to use templates over for-each, you could do this

<xsl:apply-templates select="short_name/value"> 
   <xsl:sort select="."/> 
</xsl:apply-templates> 

You wouldn’t need a matching template for the value element unless you wanted to output anything other than the text value, as the default behaviour of the XSLT processor will be output the text in this case.

One thing to note, is that in your sample, you will only ouptut one option element. Are you sure you don’t want multiple ones, one for each id or short_name. It depends on your XML input sample, of course, but suppose you had XML like this

<people>
 <person><id><value>3</value></id><short_name><value>C</value></short_name></person>
 <person><id><value>1</value></id><short_name><value>A</value></short_name></person>
 <person><id><value>2</value></id><short_name><value>B</value></short_name></person>
</people>

Then, if you use the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="people">
      <xsl:apply-templates select="person">
         <xsl:sort select="short_name/value"/>
      </xsl:apply-templates>
   </xsl:template>
   <xsl:template match="person">
      <option value="{id/value}">
         <xsl:value-of select="short_name/value"/>
      </option>
   </xsl:template>
</xsl:stylesheet>

Then the following is output

<option value="1">A</option>
<option value="2">B</option>
<option value="3">C</option>