Question

I’m working on a perl script that parses reddit’s JSON using the JSON module.

However I do have the problem of being very new to both perl and json.

I managed to parse the front page and subreddits successfully, but the comments have a different structure and I can’t figure out how to access the data I need.

Here’s the code that successfully finds the “data” hash for the front page and subreddits:

foreach my $children(@{$json_text->{"data"}->{"children"}}) #For values of children.
{
    my $data = $children->{"data"}; #accessing each data hash.
    my %phsh = ();                  #my hash to collect and print.

            $phsh{author} = $data->{"author"};#Here I get the "author" value from "data"
*Etc....

This successfully gets what I need from http://www.reddit.com/.json

But when I go to the json of a comment, this one for example, it has a different format and I can’t figure out how to parse it. If I try the same thing as before my parser crashes, saying it is not a HASH reference.

So my question is: How do access the “children” in the second JSON? I need to get both the data for the Post and the data for the comments. Can anybody help?

Thanks in advance!
(I know it may be obvious, but I’m running on very little sleep XD)

Answer 1

You need to either look at the JSON data or dump the decoded data to see what form it takes. The comment data, for example is an array at the top level.

Here is some code that prints the body field of all top-level comments. Note that a comment may have an array of replies in its replies field, and each reply may also have replies in turn.

Depending on what you want to do you may need to check whether a reference is to an array or a hash by checking the value returned by the ref operator.

use strict;
use warnings;

binmode STDOUT, ':utf8';

use JSON;
use LWP;
use Data::Dump;

my $ua = LWP::UserAgent->new;
my $resp = $ua->get('http://www.reddit.com/r/funny/comments/wx3n5/caption_win.json');
die $resp->status_line unless $resp->is_success;

my $json = $resp->decoded_content;
my $data = decode_json($json);

die "Error: $data->{error}" if ref $data eq 'HASH' and exists $data->{error};

dd $data->[1]{data}{children}[0];
print "\n\n";

my $children = $data->[1]{data}{children};
print scalar @$children, " comments:\n\n";

for my $child (@$children) {
  print $child->{data}{body}, "\n";
}