Question

In my table, I have a varchar column whereby multi-values are stored. An example of my table:

RecNum           |  Title   |  Category
-----------------------------------------
wja-2012-000001  |  abcdef  |  4,6
wja-2012-000002  |  qwerty  |  1,3,7
wja-2012-000003  |  asdffg  |   
wja-2012-000004  |  zxcvbb  |  2,7
wja-2012-000005  |  ploiuh  |  3,4,12

The values in the Category column points to another table.

How can I return the relevant rows if I want to retrieve the rows with value 1,3,5,6,8 in the Category column?

When I tried using IN, I get the ‘Conversion failed when converting the varchar value ‘1,3,5,6,8’ to data type int’ error.

Answer 1

Breaking the Categories out into a separate table would be a better design if that’s a change you can make… otherwise, you could create a function to split the values into a table of integers like this:

CREATE FUNCTION dbo.Split(@String varchar(8000), @Delimiter char(1))
returns @temptable TABLE (id int)
as
begin
    declare @idx int
    declare @slice varchar(8000)

    select @idx = 1
        if len(@String)<1 or @String is null  return

    while @idx!= 0
    begin
        set @idx = charindex(@Delimiter,@String)
        if @idx!=0
            set @slice = left(@String,@idx - 1)
        else
            set @slice = @String

        if(len(@slice)>0)
            insert into @temptable(id) values(convert(int, @slice))

        set @String = right(@String,len(@String) - @idx)
        if len(@String) = 0 break
    end
return
end

Then call it from your query:

SELECT ...
FROM ...
WHERE @SomeID IN (SELECT id FROM dbo.Split(Category, ','))

Or if you’re looking to provide a list of categories as an input parameter (such as ‘1,3,5,6,8’), and return all records in your table that contain at least one of these values, you could use a query like this:

SELECT ...
FROM ...
WHERE
    EXISTS (
        select 1
        from dbo.Split(Category, ',') s1
        join dbo.Split(@SearchValues, ',') s2 ON s1.id = s2.id
    )