Question

I’ve 2 arrays @arr & @arr1 each having 10 elements stored in it.
I need to print a table with header.
I need to load these array values into table of 10 rows & 2 columns.

@arr values into 1st column & `@arr1` into second column.

Table should like something as displayed here. How can I do it in perl scripting?

Answer 1

You can merge your arrays with map. This easily extends to more columns as well.

#!/usr/bin/env perl
use strict;
use warnings;
use Text::Table;

my @arr = 'a' .. 'j';
my @arr1 = 1 .. 10;

my $tb = Text::Table->new("Col 1", "Col 2");
$tb->load( map [$arr[$_], $arr1[$_]], 0 .. $#arr );

print $tb;

Output:

Col 1 Col 2
a      1   
b      2   
c      3   
d      4   
e      5   
f      6   
g      7   
h      8   
i      9   
j     10

If you want to add borders, you can do something like this instead:

my $tb = Text::Table->new(
    {is_sep => 1, title => '| ', body => '| '},
    "Col 1",
    {is_sep => 1, title => ' | ', body => ' | '},
    "Col 2",
    {is_sep => 1, title => ' |', body => ' |'},
);

$tb->load(map [$arr[$_], $arr1[$_]], 0 .. $#arr);

print $tb->rule('-', '+');

for (0 .. @arr) {
    print $tb->table($_);
    print $tb->rule('-', '+');
}

Everything above my $tb = ... is unchanged. Personally I’m not a big fan of ascii borders though.