Question

I’ve created a class in coffeescript with a randomInt method that generates x and y instance variables. However when I create objects from this class the x and y values are the different but consistent for both.

Here is the code to demonstrate: http://jsfiddle.net/paulmason411/BvPBG/

class Shape

  getRandomInt = (min, max) ->
    Math.floor(Math.random() * (max - min + 1)) + min

  y: getRandomInt(1,100)
  x: getRandomInt(1,100)

shape1 = new Shape
shape2 = new Shape

alert(shape1.x)
alert(shape2.x)

alert(shape1.y)
alert(shape2.y)​

I need each alerted value to be different.

I searched for a solution and in other programming languages they use srand() however js doesn’t have this native function.

Answer 1

Create “instance variables” of x and y (the @ makes them such vars):

class Shape

  constructor: ->
    @x = Shape::getRandomInt(1,100)
    @y = Shape::getRandomInt(1,100)

  getRandomInt: (min, max) ->
    Math.floor(Math.random() * (max - min + 1)) + min


shape1 = new Shape
shape2 = new Shape

console.log(shape1.x)
console.log(shape2.x)
console.log(shape1.y)
console.log(shape2.y)

which printed:

48
13
9
86

Note that the getRandomInt function is added to Shape.prototype, and Shape::getRandomInt(1,100) is identical to Shape.prototype.getRandomInt(1,100).