Question

Reading “Real World Haskell”, on page 95 the author provides an example:

myFoldl f z xs = foldr step id xs z
    where step x g a = g (f a x)

My question is: Why does this code compile? foldr takes only three arguments – but here, it is passed four: step, id, xs, z.

For example, this doesn’t work (because sum expects one):

sum filter odd [1,2,3]

instead I must write:

sum $ filter odd [1,2,3]

Answer 1

Here’s the type of foldr:

Prelude> :t foldr
foldr :: (a -> b -> b) -> b -> [a] -> b

Can we figure out how it becomes a four-argument function? Let’s give it a try!

1. we’re giving it id :: d -> d as the second parameter (b), so let’s substitute that into the type:

   (a -> (d -> d) -> (d -> d)) -> (d -> d) -> [a] -> (d -> d)
   

2. in Haskell, a -> a -> a is the same as a -> (a -> a), which gives us (removing the last set of parentheses):

   (a -> (d -> d) -> (d -> d)) -> (d -> d) -> [a] -> d -> d
   

3. let’s simplify, by substituting e for (a -> (d -> d) -> (d -> d)) and f for (d -> d), to make it easier to read:

   e -> f -> [a] -> d -> d
   

So we can plainly see that we’ve constructed a four-argument function! My head hurts.

---

Here’s a simpler example of creating an n + 1-argument function from an n-arg func:

Prelude> :t id
id :: a -> a

id is a function of one argument.

Prelude> id id id id id 5
5

But I just gave it 5 args!