Question

Suppose i have this class:

class Foo
 Public Property a() As Integer
 Private _l As List(Of Integer) = New List(Of Integer)
 Public Property l() As List(Of Integer)
    Get
     Return _l
    End Get
    Set(value As List(Of Integer))
     _l = value
    End Set
 End Property    
end class

I am trying to use initializer list to initialize the properties:

Dim f as Foo = New Foo With {.a = 1, .l.Add(1)}

The above doesn’t work. I am getting a bit confused here. Now, in an initializer list from what i understand, i can initialize the collection like this:

Dim f as Foo = New Foo With {.a = 1, .l = New List(Of Integer){1}}

But what i need to do, since _l is already pointing to an object when i say New Foo, is only add the elements without saying ..., .l = New List(Of Integer){1}}
. Why isn’t it working?

Answer 1

It’s possible using collection initializer syntax, i.e. Dim f As New Foo From {1, 2, 3} (see below). However, this has a few drawbacks:

• You cannot use collection initializer syntax and object initializers (e.g. With {.a = 1}) at the same time. Thus, you’ll have to move initialization of property a to a constructor.
• Your class must implement IEnumerable and have an Add method.

That said, here is a working example:

Class Foo
    Implements IEnumerable

    Public Property a() As Integer
    Private _l As List(Of Integer) = New List(Of Integer)
    Public Property l() As List(Of Integer)
        Get
            Return _l
        End Get
        Set(value As List(Of Integer))
            _l = value
        End Set
    End Property

    Public Sub New(ByVal a As Integer)
        Me.a = a
    End Sub

    Public Sub Add(ByVal item As Integer)
        _l.Add(item)
    End Sub

    Public Function GetEnumerator() As IEnumerator Implements IEnumerable.GetEnumerator
        Return _l.GetEnumerator()
    End Function
End Class

And it can be used as follows:

Dim f As New Foo(1) From {1, 2, 3}   ' sets a to 1 and adds 1, 2 and 3 to the list