Question

The SO Question has lead me to the following question.

If a table has 16 rows I’d like to add a field to the table with the numbers 1,2,3,4,5,…,16 arranged randomly i.e in the ‘RndVal’ field for row 1 this could be 2, then for row 2 it could be 5 i.e each of the 16 integers needs to appear once without repetition.

Why doesn’t the following work? Ideally I’d like to see this working then to see alternative solutions.

This creates the table ok:

IF OBJECT_ID('tempdb..#A') IS NOT NULL BEGIN DROP TABLE #A END
IF OBJECT_ID('tempdb..#B') IS NOT NULL BEGIN DROP TABLE #B END
IF OBJECT_ID('tempdb..#C') IS NOT NULL BEGIN DROP TABLE #C END
IF OBJECT_ID('tempdb..#myTable') IS NOT NULL BEGIN DROP TABLE #myTable END

CREATE TABLE #B (B_ID INT)
CREATE TABLE #C (C_ID INT)

INSERT INTO #B(B_ID) VALUES
    (10),
    (20),
    (30),
    (40)
INSERT INTO #C(C_ID)VALUES
    (1),
    (2),
    (3),
    (4)

CREATE TABLE #A 
    (
    B_ID INT
    , C_ID INT
    , RndVal INT
    )

INSERT INTO #A(B_ID, C_ID, RndVal)  
SELECT 
        #B.B_ID
        , #C.C_ID
        , 0 
FROM #B CROSS JOIN #C; 

Then I’m attempting to add the random column using the following. The logic is to add random numbers between 1 and 16 > then to effectively overwrite any that are duplicated with other numbers > in a loop …

SELECT 
    ROW_NUMBER() OVER(ORDER BY B_ID) AS Row
    , B_ID
    , C_ID
    , RndVal
INTO #myTable
FROM #A

DECLARE @rowsRequired INT = (SELECT COUNT(*) CNT FROM #myTable)
DECLARE @i INT = (SELECT @rowsRequired - SUM(CASE WHEN RndVal > 0 THEN 1 ELSE 0 END) FROM #myTable)--0


DECLARE @end INT = 1
WHILE @end > 0 
    BEGIN

            SELECT @i = @rowsRequired -  SUM(CASE WHEN RndVal > 0 THEN 1 ELSE 0 END) FROM #myTable
            WHILE @i>0
                BEGIN

                    UPDATE x
                    SET x.RndVal = FLOOR(RAND()*@rowsRequired)
                    FROM #myTable x
                    WHERE x.RndVal = 0 

                    SET @i = @i-1
                END 

         --this is to remove possible duplicates
            UPDATE c 
            SET c.RndVal = 0 
            FROM 
                #myTable c
                INNER JOIN 
                    (
                    SELECT RndVal
                    FROM #myTable
                    GROUP BY RndVal 
                    HAVING COUNT(RndVal)>1
                    ) t
                    ON 
                        c.RndVal = t.RndVal

         SET @end = @@ROWCOUNT

    END

TRUNCATE TABLE #A
INSERT INTO #A
SELECT 
    B_ID
    , C_ID
    , RndVal
FROM #myTable

If the original table has 6 rows then the result should end up something like this

B_ID|C_ID|RndVal
----------------
    |    | 5 
    |    | 4
    |    | 1
    |    | 6
    |    | 3
    |    | 2

Answer 1

I don’t understand your code, frankly

This will update each row with a random number, non-repeated number between 1 and the number of rows in the table

UPDATE T
SET SomeCol = T2.X
FROM
   MyTable T
   JOIN
   (
   SELECT
      KeyCol, ROW_NUMBER() OVER (ORDER BY NEWID()) AS X
   FROM 
      MyTable
   ) T2 ON T.KeyCol = T2.KeyCol 

This is more concise but can’t test to see if it works as expected

UPDATE T
SET SomeCol = X
FROM
   (
   SELECT
      SomeCol, ROW_NUMBER() OVER (ORDER BY NEWID()) AS X
   FROM 
      MyTable
   ) T