Question

To learn Clojure, I’m solving the problems at 4clojure. I’m currently cutting my teeth on question 164, where you are to enumerate (part of) the language a DFA accepts. An interesting condition is that the language may be infinite, so the solution has to be lazy (in that case, the test cases for the solution (take 2000 ....

I have a solution that works on my machine, but when I submit it on the website, it blows the stack (if I increase the amount of acceptable strings to be determined from 2000 to 20000, I also blow the stack locally, so it’s a deficiency of my solution).

My solution[1] is:

(fn [dfa]
  (let [start-state (dfa :start)
        accept-states (dfa :accepts)
        transitions (dfa :transitions)]
    (letfn [
      (accept-state? [state] (contains? accept-states state))

      (follow-transitions-from [state prefix]
          (lazy-seq (mapcat 
            (fn [pair] (enumerate-language (val pair) (str prefix (key pair))))
            (transitions state))))

      (enumerate-language [state prefix]
        (if (accept-state? state) 
          (cons prefix (follow-transitions-from state prefix))
          (follow-transitions-from state prefix)))
      ]   
      (enumerate-language start-state ""))
  )
)

it accepts the DFA

'{:states #{q0 q1 q2 q3}
              :alphabet #{a b c}
              :start q0
              :accepts #{q1 q2 q3}
              :transitions {q0 {a q1}
                            q1 {b q2}
                            q2 {c q3}}}

and returns the language that DFA accepts (#{a ab abc}). However, when determining the first 2000 accepted strings of DFA

(take 2000 (f '{:states #{q0 q1} 
                           :alphabet #{0 1}
                           :start q0
                           :accepts #{q0}
                           :transitions {q0 {0 q0, 1 q1} 
                                         q1 {0 q1, 1 q0}}}))

it blows the stack. Obviously I should restructure the solution to be tail recursive, but I don’t see how that is possible. In particular, I don’t see how it is even possible to combine laziness with tail-recursiveness (via either recur or trampoline). The lazy-seq function creates a closure, so using recur inside lazy-seq would use the closure as the recursion point. When using lazy-seq inside recur, the lazy-seq is always evaluated, because recur issues a function call that needs to evaluate its arguments.

When using trampoline,I don’t see how I can iteratively construct a list whose elements can be lazily evaluated. As I have used it and see it used, trampoline can only return a value when it finally finishes (i.e. one of the trampolining functions does not return a function).

Other solutions are considered out of scope

I consider a different kind of solution to this 4Clojure problem out of scope of this question. I’m currently working on a solution using iterate, where each step only calculates the strings the ‘next step’ (following transitions from the current statew) accepts, so it doesn’t recurse at all. You then only keep track of current states and the strings that got you into that state (which are the prefixes for the next states). What’s proving difficult in that case is detecting when a DFA that accepts a finite language will no longer return any results. I haven’t yet devised a proper stop-criterion for the take-while surrounding the iterate, but I’m pretty sure I’ll manage to get this solution to work. For this question, I’m interested in the fundamental question: can laziness and tail-recursiveness be combined or is that fundamentally impossible?

[1] Note that there are some restrictions on the site, like not being able to use def and defn, which may explain some peculiarities of my code.

Answer 1

The problem is that you are building something that looks like:

(mapcat f (mapcat f (mapcat f ...)))

Which is fine in principle, but the elements on the far right of this list don’t get realized for a long time, and by the time you do realize them, they have a huge stack of lazy sequences that need to be forced in order to get a single element.

If you don’t mind a spoiler, you can see my solution at https://gist.github.com/3124087. I’m doing two things differently than you are, and both are important:

1. Traversing the tree breadth-first. You don’t want to get “stuck” in a loop from q0 to q0 if that’s a non-accepting state. It looks like that’s not a problem for the particular test case you’re failing because of the order the transitions are passed to you, but the next test case after this does have that characteristic.
2. Using doall to force a sequence that I’m building lazily. Because I know many concats will build a very large stack, and I also know that the sequence will never be infinite, I force the whole thing as I build it, to prevent the layering of lazy sequences that causes the stack overflow.

Edit: In general you cannot combine lazy sequences with tail recursion. You can have one function that uses both of them, perhaps recurring when there’s more work to be done before adding a single element, and lazy-recurring when there is a new element, but most of the time they have opposite goals and attempting to combine them incautiously will lead only to pain, and no particular improvements.