Question

1
2
3
4  
.
.

So I have a sequence of numbers running from 1-20. I have the number “1” on top selected and I would like to search the entire column and find the number “9”. The code works when I don’t name the range “rng”; it finds the number and selects. But the code stops working when I name the range of number. What’s wrong with the range function? could it be that if I define Dim rng as Range that when I later define the "Set rng=" I cannot have the ".Select" or ".Copy" extension on the end?

Sub macro2()

Dim rng As Range
Set rng = Range(ActiveCell, ActiveCell.End(xlDown)).Select
rng.Find(10).Select

End Sub

Also, If I want to sum the entire column from 1-20, on the last cell below the number “20” should I use the following code? because the application object doesn’t seem to do it. Thank you!

rng.End(xlDown).Offset(1, 0).Select
Application.WorksheetFunction.Sum (rng.Value)

Answer 1

To look for 10 in the active column you could try this (which ends up selecting the first 10 – although Select in vba isn’t normally needed other than taken the user to location at code end)

• test that the found range exists (ie you can find 10 before proceeding)
• you should also use xlWhole to avoid matching 100 if the current default for [lookAt] is xlPart
• using search [After] as Cells(1, ActiveCell.Column , and [Search Direction] as xlNext finds the first value looking down.

code

Sub QuickFind()
Dim rng1 As Range
Set rng1 = ActiveCell.EntireColumn.Find(10, Cells(1, ActiveCell.Column), xlFormulas, xlWhole, , xlNext)
If Not rng1 Is Nothing Then
Application.Goto rng1
Else
MsgBox "10 not found"
End If
End Sub

Part 2

Sub Other()
Dim rng1 As Range
Set rng1 = Range(Cells(1, ActiveCell.Column), Cells(Rows.Count, ActiveCell.Column).End(xlUp))
rng1.Cells(rng1.Cells.Count).Offset(1, 0) = Application.WorksheetFunction.Sum(rng1.Value)
End Sub