Question

5 monkey share n peaches, they cannot distribute equally. So the first monkey dump 1 peach, and total number of peaches can be divided by 5, and the first monkey took his part.

Then is the second monkey, -1 peach, can be divided by 5 and took his part.
Until the fifth monkey finished all the steps. There may be some peaches still left.

Give the minimum number of peaches that satisfy this condition.

perl code 1:

#!/usr/bin/perl -w
for $n (0..10000){      #this is basic idea but code is too messy !
    if( ($n-1) % 5 == 0 ){
     $remain = 4/5 * ($n -1 );
         if( ($remain - 1) % 5 == 0){
           $remain = 4/5 * ($remain -1 );
           if( ($remain - 1) % 5 == 0){
               $remain = 4/5 * ($remain -1 );
               if( ($remain - 1) % 5 == 0){
                   $remain = 4/5 * ($remain -1 );
                   if( ($remain - 1) % 5 == 0){
                      $remain = 4/5 * ($remain -1 );
                      print "remain: $remain original: $n\n";
                   }
               }
            }
          }
     }
 }

perl code 2:

sub doit($){
    ($n) = @_;
    if( ($n - 1) % 5 ==0 ){ #if can be distributed by 5 monkey
       $n = ($n - 1) * 4/5;  #commit distribute
       return $n;
    }else{
       return -1;  #fail
    }
}

for $n (0..10000){   #restriction
    $r = $n;    #"recursively" find solution
    $o = $n;    #backup n
    $count = 0;
    for ($i = 0; $i < 5; $i++){  #assume there is 5 monkey, it can be changed
       $r = doit($r);
    if($r == -1){   #skip once fail
        last;
    }
    $count++;
    }
    if($count == 5){ # if pass 5 test, then you found the number !
       print "now ".$r."\n";
       print "origin ".$o."\n";
    }
}

I am thinking to cut some code. But felt hard. Can anyone help ?

Answer 1

First of all, you really should use strict and warnings pragmas at the top of your scripts. Your $n usage is especially worrisome. In the future, if you declare variables with my but use the same name, you convey the fact that they will represent the same quantity, without the fear that they might collide.

Anyway here is a slightly polished, and more importantly strict and warnings safe version:

#!/usr/bin/env perl

use strict;
use warnings;

sub doit {
    my ($n) = @_;
    if( ($n - 1) % 5 ==0 ){ #if can be distributed by 5 monkey
       $n = ($n - 1) * 4/5;  #commit distribute
       return $n;
    } else {
       return undef;  #fail
    }
}

OUTER: for my $n (0..10000){   #restriction
    my $r = $n;    #"recursively" find solution
    for (1..5){  #assume there is 5 monkey, it can be changed
       $r = doit($r);
       next OUTER unless defined $r;
    }
    # if code gets here, then it passed 5 test, then you found the number !
    print "now: $r\torigin: $n\n";
}

And now, if you really want to be fun with it (don’t use this in production, readability first! ):

#!/usr/bin/env perl

use strict;
use warnings;

OUTER: for my $n (0..10000){ 
    my $r = $n;
    $r = ($r - 1) % 5 ? next OUTER : 4/5 * ($r - 1) for (1..5);
    print "now: $r\torigin: $n\n";
}

or even golfed:

for(0..10000){$r=$n=$_;map$r*=--$r%5?next:4/5,1..5;print"now: $r\torigin: $n\n"}