Question

about the define-match-expansion, there are rare materials and example codes to illustrate the concepts. I am having a hard time to “decode” what the documentation says:

(define-match-expander id proc-expr)
(define-match-expander id proc-expr proc-expr)

Binds id to a match expander.

The first proc-expr subexpression must
evaluate to a transformer that
produces a pat for match. Whenever id
appears as the beginning of a pattern,
this transformer is given, at
expansion time, a syntax object
corresponding to the entire pattern
(including id). The pattern is the
replaced with the result of the
transformer.

A transformer produced by a second
proc-expr subexpression is used when
id is used in an expression context.
Using the second proc-expr, id can be
given meaning both inside and outside
patterns.

Can anyone give some example codes to illustrate the two usages of the define-match-expander here?

Answer 1

The idea behind match-expander is that you can extend the ‘match’ form to handle new pattern forms of your own design.

So, here’s a (somewhat pointless) example that defines an "aba" match form that matches patterns of one thing followed by another thing followed by the first thing again (hence, "aba"):

#lang racket

(define-match-expander aba
  (lambda (stx)
    (syntax-case stx ()
      [(_ a b) #'(list a b a)])))

(match '(3 4 3)
  [(aba x y) (printf "x = ~a, y = ~a" x y)])

The second form allows you to add a separate expansion to be used outside of match patterns, like this:

#lang racket

(define-match-expander aba
  (lambda (stx)
    (syntax-case stx ()
      [(_ a b) #'(list a b a)]))
  (lambda (stx)
    #'(error "please don't use aba outside of patterns.")))

(match '(3 4 3)
  [(aba x y) (printf "x = ~a, y = ~a\n" x y)])

(aba x y)

Caveat: whuffo the extra pair of parens around the pattern? Not sure, sorry.