Question

All,

I’m new to XSLT and facing a typical problem. Below is the problem details

Based on the data below, i needed to show ItemA/ANum element only when its of AName BBC and not part of ItemB/tempBNum

So desired result for the below data should be 0214,BBC, since its part of the ItemA, also is a BBC is does not appear in ItemB.

<myData>
<ItemA>
    <ANum>0213</ANum>
    <AName>OOC</AName>
</ItemA>
<ItemA>
    <ANum>0031</ANum>
    <AName>BBC</AName>
</ItemA>
<ItemA>
    <ANum>0214</ANum>
    <AName>BBC</AName>
</ItemA>
<ItemA>
    <ANum>0044</ANum>
    <AName>BBC</AName>
</ItemA>

<ItemB>
    <tempBNum>0031</tempBNum>
</ItemB>
<ItemB>
    <tempBNum>0044</tempBNum>
</ItemB>
</myData>

For this end, I tried putting in a logic of having Nested For Loops, only problem being nested loop should break when ItemAObj/ANum = tempBNum, but its not breaking and producing duplicate results.

  <xsl:for-each select="myData/ItemA">
    <xsl:variable name="ItemAObj" select="." />
    Num = <xsl:value-of select="$ItemAObj/ANum"/>
    <xsl:for-each select="/myData/ItemB">
    <xsl:choose>
        <xsl:when test="$ItemAObj/ANum!=tempBNum and $ItemAObj/AName='BBC'"> <xsl:value-of select="tempBNum"/>
        <xsl:text> </xsl:text>
    </xsl:when>
        </xsl:choose>
        </xsl:for-each>
  </xsl:for-each>

Any help on this will be greatly appreciated.

Answer 1

You don’t need to use any xsl:for-each to solve the problem, much more you don’t need nested xsl:for-each.

In fact, the wanted ItemA elements can be selected with a single XPath expression:

/*/ItemA[AName = 'BBC' 
       and 
         not(ANum = /*/ItemB/tempBNum)
        ]

Therefore a simple XSLT transformation that evaluates the above XPath expression and copies the result to the output is:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
     <xsl:copy-of select=
     "/*/ItemA[AName = 'BBC' and not(ANum = /*/ItemB/tempBNum)]"/>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied to the provided XML document:

<myData>
    <ItemA>
        <ANum>0213</ANum>
        <AName>OOC</AName>
    </ItemA>
    <ItemA>
        <ANum>0031</ANum>
        <AName>BBC</AName>
    </ItemA>
    <ItemA>
        <ANum>0214</ANum>
        <AName>BBC</AName>
    </ItemA>
    <ItemA>
        <ANum>0044</ANum>
        <AName>BBC</AName>
    </ItemA>
    <ItemB>
        <tempBNum>0031</tempBNum>
    </ItemB>
    <ItemB>
        <tempBNum>0044</tempBNum>
    </ItemB>
</myData>

the wanted, correct result is produced:

<ItemA>
   <ANum>0214</ANum>
   <AName>BBC</AName>
</ItemA>

If we want just the values of the text nodes, just use the string() function:

string(/*/ItemA[AName = 'BBC' and not(ANum = /*/ItemB/tempBNum)])

Then the so modified transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:copy-of select=
     "string(/*/ItemA[AName = 'BBC' and not(ANum = /*/ItemB/tempBNum)])"/>
 </xsl:template>
</xsl:stylesheet>

when applied on the same XML document (above), produces:

    0214
    BBC

Note: If performance starts to matter, using keys could be the next step to increase the efficiency of the transformation.