Question

Are there any AWK syntax checkers? I’m interested in both minimal checkers that only flag syntax errors and more extensive checkers along the lines of lint.

It should be a static checker only, not dependent on running the script.

Answer 1

If you prefix your Awk script with BEGIN { exit(0) } END { exit(0) }, you’re guaranteed that none of your of code will run. Exiting during BEGIN and END prevents other begin and exit blocks from running. If Awk returns 0, your script was fine; otherwise there was a syntax error.

If you put the code snippet in a separate argument, you’ll get good line numbers in the error messages. This invocation…

gawk --source 'BEGIN { exit(0) } END { exit(0) }' --file syntax-test.awk

Gives error messages like this:

gawk: syntax-test.awk:3:   x = f(
gawk: syntax-test.awk:3:         ^ unexpected newline or end of string

GNU Awk’s --lint can spot things like global variables and undefined functions:

gawk: syntax-test.awk:5: warning: function `g': parameter `x' shadows global variable
gawk: warning: function `f' called but never defined

And GNU Awk’s --posix option can spot some compatibility problems:

gawk: syntax-test.awk:2: error: `delete array' is a gawk extension

Update: BEGIN and END

Although the END { exit(0) } block seems redundant, compare the subtle differences between these three invocations:

$ echo | awk '
  BEGIN { print("at begin") }
  /.*/ { print("found match") }
  END { print("at end") }'
at begin
found match
at end

$ echo | awk '
  BEGIN { exit(0) }
  BEGIN { print("at begin") }
  /.*/ { print("found match") }
  END { print("at end") }'
at end

$ echo | awk '
  BEGIN { exit(0) } END { exit(0) }
  BEGIN { print("at begin") }
  /.*/ { print("found match") }
  END { print("at end") }'

In Awk, exiting during BEGIN will cancel all other begin blocks, and will prevent matching against any input. Exiting during END is the only way to prevent all other event blocks from running; that’s why the third invocation above shows that no print statements were executed. The GNU Awk User’s Guide has a section on the exit statement.