Question

As the title says, is there a way to alter the ResourceManager’s getStringArray() in a way that it splits the resources by semicolon, not comma?

The actual method can be found in the ResourceManagerImpl class, which can be found in in the package mx.resources.
Overriding that method would be fine, but ideally I’d like to write my own getStringArray with a variable separator, however, there seems to be no way of extending either the ResourceManager or ResourceManagerImpl class to somehow add that method.

Anyone got a clue what to do here?

Answer 1

The problem is not that you can’t extend ResourceManagerImpl since it’s not final, but rather that you have to be able to register your implementation with the application instead of the default one. And doing this is a bit tricky.

So first create your implementation:

public class MyResourceManager extends ResourceManagerImpl {

    private static var instance:IResourceManager;

    static public function getInstance():IResourceManager
    {
        if (!instance) instance = new MyResourceManager();
        return instance;
    }

    override public function getStringArray(bundleName:String,
                                            resourceName:String,
                                            locale:String = null):Array {
        //do your stuff
    }

}

So we’ve overriden the getStringArray method. Notice that we’ve done the same for getInstance, because we want it to return a new instance of MyResourceManager instead of ResourceManagerImpl (we don’t have to mark override because it’s a static method). Also, you may have to write some import statements manually, because some of the classes you’re using are marked as ‘excluded’.

Now we have to tell Flex to use MyResourceManager instead of ResourceManagerImpl. We can do this with the following code:

import mx.core.Singleton;
Singleton.registerClass("mx.resources::IResourceManager", MyResourceManager);

The problem is that we have to do this before Flex registers ResourceManagerImpl, because you can’t override it once it’s registered. For this we need to create a custom preloader in which we do the registering (sadly, the Application’s ‘preinitialize’ phase is not early enough).

public class RegisteringPreloader extends DownloadProgressBar {

    override public function initialize():void {
        super.initialize();
        Singleton.registerClass("mx.resources::IResourceManager", 
                                MyResourceManager);
    }

}

Now assign the custom preloader to the application and we’re done:

<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
               xmlns:s="library://ns.adobe.com/flex/spark" 
               xmlns:mx="library://ns.adobe.com/flex/mx"
               preloader="RegisteringPreloader" >

For further info I refer you to a fairly similar, but somewhat more elaborate answer that I wrote for a different question: Is there a way to listen for events on the pop up manager class?