Question

Assume we have a sequence of bytes with header of ‘807F’ which is input to PC through RS232. for example “… 80 7F 4B 97 80 7F 21 3A 80 7F … ” in which “21 3A” is our data in bold package and 21 is MSB and 3A is LSB. how can we extract data from the sequence in DELPHI?

Answer 1

How your data is stored is a bit unclear, but assuming it is stored in a TBytes array, here is some code to unpack the data:

procedure ExtractWordFromRS232Data( a : TBytes);
var
  i: integer;
  myWord: word;
begin
  // a is a TBytes buffer from reading the RS232 port
  i := 0;
  while (i < Length(a)-3) do 
  begin
    if (a[i] = $80) and (a[i+1] = $7F) then 
    begin
      myWord := (a[i+2] shl 8) + a[i+3];
      // Do something with myWord
      Inc(i,4);
    end
    else
      Inc(i);
  end;
end;

It will search for first excistance of the header $80 $7F and unpack the following two bytes into a word. Do what you want with the word. The search then continues until the end of the input data array.

Update:
It’s still unclear what you really want, but here is some code where data is coming to the procedure via an event.

var
  gData : array[1..4] of byte;
  gIX : integer;

gIx := 1; // initialized at start

procedure InterpretIndataEvent( b : byte);
var
  i : integer;
  myWord : word;
begin
  gData[gIx] := b;
  if (gIx = 4) then
  begin
    if (gData[1] = $80) and (gData[2] = $7f) then
    begin
      myWord := (gData[3] shl 8) + gData[4];
      // do something with myWord
      gIx := 1;
    end
    else
    begin
      for i := 1 to 3 do gData[i] := gData[i+1];
    end;
  end
  else
    Inc(gIx);
end;

Update 2:

By the look of the comments, it seems as though the data is coming as ascii characters.

Then the decoding procedure will look something like this (including a small test) :

uses
  System.SysUtils;

var
  gData : string[8] = '12345678'; // Old fixed size ansistring type
  gIX : integer = 1;

procedure InterpretIndataEvent( a : AnsiChar);
var
  i : integer;
  myWord : word;
begin
  gData[gIx] := a;
  if (gIx = 8) then
  begin
    if (Copy(gData,1,4) = '807F') then
    begin
      myWord := StrToInt('$'+Copy(gData,5,4));
      // do something with myWord
      WriteLn(IntToHex(myWord,4));
      gIx := 1;
    end
    else
    begin
      for i := 1 to 7 do gData[i] := gData[i+1];
      // During startup or if a character is missed we end up here.
      // These events can be logged from here.
    end;
  end
  else
    Inc(gIx);
end;

const
  testBuf : string[8] = '807F213A';
var
  i : integer;

begin
  for i := 1 to 8 do
    InterpretIndataEvent(testBuf[i]);
  ReadLn;

end.