Question

Assuming that I have this:

<nodes>
<node>
    <number>1</number>
    <name>"ABC"</name>
    <comment>"blah"</comment>
</node>

<node>
    <number>2</number>
    <name>"DEF"</name>
    <comment>"blah blah"</comment>
</node>

<node>
    <number>3</number>
    <name>"XYZ"</name>
    <comment>"blah blah blah"</comment>
</node>
</nodes>

I would like to end up with this:

<nodes>
<node>
    <number>3</number>
    <name>"XYZ"</name>
    <comment>"blah blah blah"</comment>
</node>

<node>
    <number>2</number>
    <name>"DEF"</name>
    <comment>"blah blah"</comment>
</node>

<node>
    <number>1</number>
    <name>"ABC"</name>
    <comment>"blah"</comment>
</node>
</nodes>

Answer 1

I. In your case the solution is as simple as this:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*">
  <nodes>
   <xsl:apply-templates select="node">
     <xsl:sort select="position()" data-type="number" order="descending"/>
   </xsl:apply-templates>
  </nodes>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document:

<nodes>
    <node>
        <number>1</number>
        <name>"ABC"</name>
        <comment>"blah"</comment>
    </node>
    <node>
        <number>2</number>
        <name>"DEF"</name>
        <comment>"blah blah"</comment>
    </node>
    <node>
        <number>3</number>
        <name>"XYZ"</name>
        <comment>"blah blah blah"</comment>
    </node>
</nodes>

the wanted, correct result is produced:

<nodes>
   <node>
      <number>3</number>
      <name>"XYZ"</name>
      <comment>"blah blah blah"</comment>
   </node>
   <node>
      <number>2</number>
      <name>"DEF"</name>
      <comment>"blah blah"</comment>
   </node>
   <node>
      <number>1</number>
      <name>"ABC"</name>
      <comment>"blah"</comment>
   </node>
</nodes>

---

II. Reversing a node-set inplace, whose nodes all belong to the same document:

Things become much more tricky if we want to reverse the nodes of a node-set and leave all other nodes in the document “as-is”.

Let’s nave this XML document:

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

We want to produce from this a document where the num elements with odd value are in the same order, but the num elements with even value come in reverse order. The result must be:

<nums>
   <num>01</num>
   <num>10</num>
   <num>03</num>
   <num>08</num>
   <num>05</num>
   <num>06</num>
   <num>07</num>
   <num>04</num>
   <num>09</num>
   <num>02</num>
</nums>

Here is the transformation that produces the wanted result:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vNodes" select="/*/*[. mod 2 = 0]"/>

 <xsl:variable name="vrtfReverse">
   <xsl:for-each select="$vNodes">
     <xsl:sort select="position()" data-type="number" order="descending"/>
     <xsl:copy-of select="."/>
   </xsl:for-each>
 </xsl:variable>

 <xsl:variable name="vReverse" select="ext:node-set($vrtfReverse)/*"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*/*">
  <xsl:choose>
   <xsl:when test="count(. | $vNodes) > count($vNodes)">
     <xsl:call-template name="identity"/>
   </xsl:when>
   <xsl:otherwise>
     <xsl:variable name="vPositionInNodeSet" select=
     "count($vNodes
             [count(.
                    | current()/preceding::node()
                    | current()/ancestor::node()
                    )
             =
              count(  current()/preceding::node()
                    | current()/ancestor::node()
                    )
             ]
            ) +1"/>

     <xsl:for-each select="$vReverse[position() = $vPositionInNodeSet]">
       <xsl:call-template name="identity"/>
     </xsl:for-each>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>