Question

Assuming using bash, having a configuration file like:

1. param-a=aaaaaa
2. param-b=bbbbbb
3. param-foo=first occurence <– Replace
4. param-c=cccccc
5. # param-foo=first commented foo <– Commented: don’t replace
6. param-d=dddddd
7. param-e=eeeeee
8. param-foo=second occurence <– Rreplace
9. param-foo=third occurence <– Last active: don’t replace
10. param-x=xxxxxx1
11. param-f=ffffff
12. # param-foo=second commented foo <– Commented: don’t replace
13. param-x=xxxxxx2

In which you can find multiple commented or uncommented lines of the param-foo,
how can you comment all the uncommented param-foos except the very last active one,
resulting in:

1. param-a=aaaaaa
2. param-b=bbbbbb
3. # param-foo=first occurence <– Replaced
4. param-c=cccccc
5. # param-foo=commented foo <– Left
6. param-d=dddddd
7. param-e=eeeeee
8. # param-foo=second occurence <– Replaced
9. param-foo=third occurence <– Left
10. param-x=xxxxxx1
11. param-f=ffffff
12. # param-foo=second commented foo <– Left
13. param-x=xxxxxx2

Two parts of the question:
1. How to do it with only one known repeating param?
(only param-foo in the example above)

2. How to do it with all multiple active params at once?

(param-foo + param-x in the example above)
Attention: In this case I don’t know previously the name of the repeating params!

Thanks

Answer 1

If awk is acceptable, this will do it for param-foo and param-x:

awk -F= -v p='param-foo param-x'  'BEGIN { 
  ARGV[ARGC++] = ARGV[ARGC - 1]
  n = split(p, t, OFS)
  for (i = 0; ++i <= n;) _p[t[i]]
  }
NR == FNR {
    $1 in _p && nr[$1] = NR
  next
  }  
$1 in nr && FNR != nr[$1] {
  $0 = "# " $0 
  }1' infile

You may use a single parameter: p=param-x or add more parameters separated by spaces: p=’param-1 param-2 … param-n’.

Edit: I’m assuming the real input file looks like this:

param-a=aaaaaa
param-b=bbbbbb
param-foo=first occurence
param-c=cccccc
# param-foo=commented foo
param-d=dddddd
param-e=eeeeee
param-foo=second occurence
param-foo=third occurence
param-x=xxxxxx1
param-f=ffffff
param-x=xxxxxx2

Let me know if it’s different.

Second edit: providing a solution for mawk users:

awk -F= -v p='param-foo param-x'  'BEGIN { 
  n = split(p, t, OFS)
  for (i = 0; ++i <= n;) _p[t[i]]
  }
NR == FNR {
    $1 in _p && nr[$1] = NR
  next
  }  
$1 in nr && FNR != nr[$1] {
  $0 = "# " $0 
  }1' infile infile

Adding solution for the latest requirement:

awk -F= 'NR == FNR {
  if (NF && !/^#/)
    _p[$1]++ && nr[$1] = NR
  next
  }    
$1 in nr && FNR != nr[$1] {
  FNR != nr[$1] && $0 = "# " $0 
  }1' infile infile