Question

Background

Obtain the value from a list of XML elements using a unique identifier.

Problem

Given an XML document of the form:

<root xmlns:r="http://internet.com/network">
<r:equipment label="network">
  <r:item id="1">computer</r:item>
  <r:item id="2">network cable</r:item>
</r:equipment>
<r:equipment label="peripheral">
  <r:item id="3">printer</r:item>
  <r:item id="4">USB cable</r:item>
</r:equipment>

<r:install>
  <r:step action="identify"><r:item id="1" />, <r:item id="2" />, <r:item id="3" />, and <r:item id="4" /></r:step>
  <r:step action="unplug"><r:item id="2" /> from <r:item id="1" /></r:step>
  <r:step action="plug"><r:item id="4" /> into <r:item id="3" /></r:step>
  <r:step action="plug"><r:item id="4" /> into <r:item id="1" /></r:step>
</r:install>
</root>

The goal is to produce the following:

1. identify computer, network cable, printer, and USB cable
2. unplug network cable from computer
3. plug USB cable into printer
4. plug USB cable into computer

I have tried the following:

<xsl:template match="r:install">
<p>
Installation
</p>
  <ol>
  <xsl:for-each select="r:step">
    <li><xsl:apply-templates select="." /></li>
  </xsl:for-each>
  </ol>
</xsl:template>

<xsl:template match="//root/r:install/r:step/r:item">
  ID: <xsl:value-of select="@id" />
</xsl:template>

In other words, I would like to match on <r:install> and then use the id attribute from any <r:item ... /> element. Each <r:step /> can have multiple <r:item id="X" /> references. These references correspond to the <r:item>...</r:item> elements within the <r:equipment ../> element list.

The id values for each <r:item /> are guaranteed unique.

I would like to avoid using an additional tag if possible (e.g., <r:item-ref id="X" />).

Question

Given <r:install><r:step action="unplug"><r:item id="4" /></r:step></r:install> and the following list:

<r:equipment label="peripheral">
  <r:item id="3">printer</r:item>
  <r:item id="4">USB cable</r:item>
</r:equipment>

What is the corresponding select XPath expression to get the value of USB cable when applying a template that hits upon <r:item id="4" />, which serves as a reference to said value, anywhere in the XML document?

Thank you!

Answer 1

This is the ideal situation to use a key to look-up your r:item values from the r:equipment elements.

<xsl:key name="equipment" match="r:equipment/r:item" use="@id" />

So, you “use” the @id attribute to look up r:equipment/r:item elements. To use this key, assuming you are positioned on one of your r:step/r:item elements, you just do this…

<xsl:value-of select="key('equipment', @id)" />

Here is the full XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:r="http://internet.com/network" exclude-result-prefixes="r">
   <xsl:output method="html" indent="yes"/>

   <xsl:key name="equipment" match="r:equipment/r:item" use="@id" />

   <xsl:template match="/root">
      <xsl:apply-templates select="r:install"/>
   </xsl:template>

   <xsl:template match="r:install">
      <p> Installation </p>
      <ol>
         <xsl:apply-templates select="r:step" />
      </ol>
   </xsl:template>

   <xsl:template match="r:step">
      <li>
         <xsl:value-of select="concat(@action, ' ')" />
         <xsl:apply-templates select="node()" />
      </li>
   </xsl:template>

   <xsl:template match="r:item"> 
      <xsl:value-of select="key('equipment', @id)" />
   </xsl:template>
</xsl:stylesheet>

When applied to your source XML, the following is produced

<p> Installation </p>
<ol>
<li>identify computer, 
            network cable, 
            printer, and 
            USB cable</li>
<li>unplug network cable from 
            computer</li>
<li>plug USB cable into 
            printer</li>
<li>plug USB cable into 
            computer</li>
</ol>