Question

Below is a VBA function that I created for use in Excel for converting a measurement of feet from a number to text. For instance, the function will take the number 1.5 and convert it to the string: 1′-6″.

For some reason though, it is incorrectly rounding the value of 11.5-inches. When a cell is set to ‘=11.5/12′ (11.5-inches expressed as feet) the result is 0.9583 with the 3 repeating. When I then pass this value to my txtfeet() function, it returns the string 1’-0″. The real answer should be the string 11 1/2″.

The function works fine for other repeating numbers like 9.5-inches (0.7916 with the 6 repeating). Weirdly, it also works fine if I pass it 1-ft and 11.5-inches (in other words, 1.9583 with the 3 repeating).

Can anyone help fix this error?

Here is the code for my function.

Public Function txtfeet(FeetIn As Double, Optional Denominator As Integer = 8)

' This function will change a decimal number of feet (FeetIn) to the text string
' representation of feet, inches, and fractional inches.
'
' It will round the fractional inches to the nearest 1/x where x is the denominator
' and is given by the user as the second argument of this function.  If a denominator
' is not given, it defaults to 8 as shown above.
'
' Modified from MrExcel.com

    ' set a variable to the integer portion of FeetIn
    NbrFeet = Fix(FeetIn)

    ' set a variable to the number of inches in decimal form
    InchIn = (FeetIn - NbrFeet) * 12

    ' set a variable to the integer portion of InchIn
    NbrInches = Fix(InchIn)

    ' set a variable to the remaining fractional inches in decimal form
    FracIn = (InchIn - NbrInches) * Denominator

    ' set a variable to be FracIn rounded to the nearest whole number
    Numerator = Application.WorksheetFunction.Round(FracIn, 0)

    ' if the fractional inches are zero, define the portion of text
    ' that will represent the fractional inches to be blank
    If Numerator = 0 Then
        FracText = ""

    ' otherwise, if the number of inches plus the fractional inches rounds up to
    ' 12, add one to NbrFeet and set NbrInches to zero and FracText to blank
    ElseIf (InchIn + (Numerator / Denominator)) = 12 Then
        NbrFeet = NbrFeet + 1
        NbrInches = 0
        FracText = ""

    ' otherwise, if the numerator equals the denominator, add one to NbrInches
    ' and set FracText to blank
    ElseIf Numerator = Denominator Then
        NbrInches = NbrInches + 1
        FracText = ""

    ' otherwise, define FracText in its simplest fractional form
    Else
        ' use a loop to get the fractional inches to their simplest form
        Do
            ' if the numerator is even, divide both numerator and divisor by 2
            If Numerator = Application.WorksheetFunction.Even(Numerator) Then
                Numerator = Numerator / 2
                Denominator = Denominator / 2
            Else
                FracText = " " & Numerator & "/" & Denominator
                Exit Do
            End If
        Loop
    End If

    ' define the output of the function as a text string of feet, inches, and
    ' fractional inches or just inches and fractional inches if NbrFeet is zero
    ' or just fractional inches if both NbrFeet and NbrInches are zero
    If NbrFeet = 0 And NbrInches = 0 And Numerator = 0 Then
        txtfeet = "0"""
    ElseIf NbrFeet = 0 And NbrInches = 0 Then
        txtfeet = Application.WorksheetFunction.Trim(FracText) & """"
    ElseIf NbrFeet = 0 Then
        txtfeet = NbrInches & FracText & """"
    Else
        txtfeet = NbrFeet & "'-" & NbrInches & FracText & """"
    End If

End Function

Answer 1

I believe your line

ElseIf (InchIn + (Numerator / Denominator)) = 12 Then
    NbrFeet = NbrFeet + 1
    NbrInches = 0
    FracText = ""

should be

ElseIf (NbrInches + (Numerator / Denominator)) = 12 Then
   NbrFeet = NbrFeet + 1
NbrInches = 0
FracText = "