Question

By using date object how we can calculate over lapping weeks?

For eg:

July 31(Tuesday) is end for the week number 38, However week number 38 ends Sunday i.e Aug 4.

However months are different

Any idea on this

Thanks all

Answer 1

In our Calendar component, we use this code to calculate the first date in a week; and I bet it could be modified to find the last Date of the Week. IT makes use of the DateUtils library

    public static const DAY_OF_MONTH:String = "date";

    /**
     * This method gets the first date of the week which the given date is in.
     * 
     * @param date  This is the date for which we want to process.
     * @param firstDayOfWeek    The first day of the week, 0 (Sunday) - 6 (Saturday); 0 is the default.  It will probably be used primarily for localization purposes.
     * 
     * @return      This returns a date representing the first day of the week.
     */
    public static function firstDateOfWeek( date:Date, firstDayOfWeek : int = 0 ):Date {
        var dayIncrement : int = dayOfWeekLocalized(date, firstDayOfWeek);

        var returnDate : Date = DateUtils.dateAdd(DateUtils.DAY_OF_MONTH,-dayIncrement,date);
        return returnDate; 

    }

    /**
     * This method returns the position of the day in a week, with respect to the firstDayOfWeek localization variable. 
     * 
     * If firstDayOfWeek is 0; then the week is display 0 (Sunday), 1 (Monday), 2 (Tuesday), 3 (Wednesday), 4 (Thursday), 5 (Friday), 6 (Saturday).  
     * So, a Sunday would return 0, a Saturday would return 6, and so on.  
     * 
     * If firstDayOfWeek is 1; then the week is displayed as 0 (Monday), 1 (Tuesday), 2 (Wednesday), 3 (Thursday), 4 (Friday), 5 (Saturday), 6 (Sunday). 
     * However, this situation will not change the date.day value.  For display purposes we need a Sunday to return 6, a Saturday to return 5, and so on.
     * 
     * This will presumably be used for display purposes.
     * 
     * @param date  This is the date to process.
     * @param firstDayOfWeek    The first day of the week, 0 (Sunday) - 6 (Saturday); 0 is the default.  It will probably be used primarily for localization purposes.
     * 
     * @return      This returns a date representing the day’s location on the localized week display.
     */
    public static function dayOfWeekLocalized( date:Date, firstDayOfWeek : int = 0 ):int {
        var result : int = date.day - firstDayOfWeek;
        if(result < 0){
            result += 7;
        }

        return result;

    }

To find the last date of a week, I suspect you can just call the firstDateOfWeek and add 6 days:

    public static function lastDateOfWeek( date:Date, firstDayOfWeek : int = 0 ):Date {
        var firstDateOfWeek : Date = firstDateOfWeek(date, firstDayOfWeek);

        var returnDate : Date = DateUtils.dateAdd(DateUtils.DAY_OF_MONTH,6,firstDateOfWeek );
        return returnDate; 
    }

Note: The second batch of code was written in a browser and is completely untested.

---

Update:
Given a specific date, you can find out the weekOfYear number using the weekOfYear method in the DateUtils library. Use the methods above to find the first and last date of the week in question

Conceptually like this:

var weekOfYear : Number = DateUtils.weekOfYear(myDate);
var firstDayOfWeek : Date = firstDateOfWeek(myDate);
var lastDayOfWeek : Date = lastDateOfWeek(myDate);