Question

Can anyone explain why ChildNodes.FindNode(”) (1) fails but ChildNodes[”] (2) succeeds? ==>

Code:

const
   cNodeSOAPEnvelope  = 's:Envelope';
   cNodeSOAPBody      = 's:Body';
   cNodeSOAPBodyFault = 's:Fault';
   cNodeSOAPHeader    = 's:Header';
   cNodeFaultCode     = 'faultcode';
   cNodeFaultString   = 'faultstring';

procedure TFrmXMLParsingTests.BtnTestClick(Sender: TObject);
var
   SoapBodyNode,
   SoapBodyFaultNode,
   SoapHeaderNode,
   FaultCodeNode,
   FaultTextNode,
   RootNode: IXmlNode;
begin
   RootNode := XMLDoc.DocumentElement;
   Assert(RootNode.NodeName = cNodeSOAPEnvelope,'Root node is not SOAP envelope');
   SoapBodyNode := RootNode.ChildNodes[cNodeSOAPBody];
   SoapBodyFaultNode := SoapBodyNode.ChildNodes[cNodeSOAPBodyFault];
   if SoapBodyFaultNode <> nil then
   begin
//      FaultCodeNode := SoapBodyFaultNode.ChildNodes.FindNode(cNodeFaultCode);     (*1*)
//      FaultTextNode := SoapBodyFaultNode.ChildNodes.FindNode(cNodeFaultString);   (*1*)
      FaultCodeNode := SoapBodyFaultNode.ChildNodes[cNodeFaultCode];                (*2*) 
      FaultTextNode := SoapBodyFaultNode.ChildNodes[cNodeFaultString];              (*2*) 
      Exit; // Nothing more to do
   end; { fault in body }
   SoapHeaderNode := RootNode.ChildNodes.FindNode(cNodeSOAPHeader);
   Assert(SoapHeaderNode <> nil,'SOAP Header not found');
end;

XML:

<s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/">
   <s:Body>
      <s:Fault>
         <faultcode xmlns:a="http://schemas.microsoft.com/exchange/services/2006/types">a:ErrorSchemaValidation</faultcode>
         <faultstring xml:lang="nl-NL">The [snip] value.</faultstring>
         <detail>
            <e:ResponseCode xmlns:e="http://schemas.microsoft.com/exchange/services/2006/errors">ErrorSchemaValidation</e:ResponseCode>
            <e:Message xmlns:e="http://schemas.microsoft.com/exchange/services/2006/errors">The request failed schema validation.</e:Message>
            <t:MessageXml xmlns:t="http://schemas.microsoft.com/exchange/services/2006/types">
               <t:LineNumber>10</t:LineNumber>
               <t:LinePosition>30</t:LinePosition>
               <t:Violation>The [snip] value.</t:Violation>
            </t:MessageXml>
         </detail>
      </s:Fault>
   </s:Body>
</s:Envelope>

Thanks
Jan

Answer 1

Read the documentation. When you access the ChildNodes[] property asking for a non-existant node, a new node will automatically be created if the doNodeAutoCreate flag is enabled in the parent XMLDocument’s Options property, otherwise an EXMLDocError exception will be raised instead.

Update: since your document contains multiple XML namespaces in it, you need to take the namespaces into account when using the ChildNodes[] property and the FindNode() method. The reason your code is not finding the <faultcode> and <faultstring> nodes correctly is because they have a different namespace (actually, they don’t have any namespace at all) than the <Fault> tag has, but the ChildNodes[] property and the 1-parameter FindNode() method expects them to have the same namespace as their parent node. When you search a namespaced node for a child node that has a different namespace, you have to include the child’s namespace in the search in order to find the child node correctly.

Try this:

uses
  ..., XmlIntf, XMLDom, XmlDoc;

const
  cSoapEnvelopeNS    = 'http://schemas.xmlsoap.org/soap/envelope/';
  cExchangeErrorsNS  = 'http://schemas.microsoft.com/exchange/services/2006/errors';
  cExchangeTypesNS   = 'http://schemas.microsoft.com/exchange/services/2006/types';

  cNodeSOAPEnvelope  = 'Envelope';
  cNodeSOAPBody      = 'Body';
  cNodeSOAPBodyFault = 'Fault';
  cNodeSOAPHeader    = 'Header';
  cNodeFaultCode     = 'faultcode';
  cNodeFaultString   = 'faultstring';
  cNodeDetail        = 'detail';
  cNodeResponseCode  = 'ResponseCode';
  cNodeMessage       = 'Message';
  cNodeMessageXml    = 'MessageXml';
  cNodeLineNumber    = 'LineNumber';
  cNodeLinePosition  = 'LinePosition';
  cNodeViolation     = 'Violation';

procedure TFrmXMLParsingTests.BtnTestClick(Sender: TObject);
var
   RootNode,
   SoapBodyNode,
   SoapBodyFaultNode,
   SoapHeaderNode,
   FaultCodeNode,
   FaultTextNode,
   DetailNode,
   ResponseCodeNode,
   MessageNode,
   MessageXmlNode,
   LineNumberNode,
   LinePositionNode,
   ViolationNode: IXMLNode;
begin
   RootNode := XMLDoc.DocumentElement;
   Assert(NodeMatches(RootNode.DOMNode, cNodeSOAPEnvelope, cSoapEnvelopeNS), 'Root node is not SOAP envelope');

   // these have the same namespace as <Envelope>
   SoapBodyNode := RootNode.ChildNodes[cNodeSOAPBody];
   SoapBodyFaultNode := SoapBodyNode.ChildNodes.FindNode(cNodeSOAPBodyFault);

   if SoapBodyFaultNode <> nil then
   begin
      // these have a different namespace than <Fault>!
      FaultCodeNode := SoapBodyFaultNode.ChildNodes.FindNode(cNodeFaultCode, '');
      FaultTextNode := SoapBodyFaultNode.ChildNodes.FindNode(cNodeFaultString, '');
      DetailNode := SoapBodyFaultNode.ChildNodes.FindNode(cNodeDetail, '');

      if DetailNode <> nil then
      begin
        // these have different namespaces than <detail>!
        ResponseCodeNode := DetailNode.ChildNodes.FindNode(cNodeResponseCode, cExchangeErrorsNS);
        MessageNode := DetailNode.ChildNodes.FindNode(cNodeMessage, cExchangeErrorsNS);
        MessageXmlNode := DetailNode.ChildNodes.FindNode(cNodeMessageXml, cExchangeTypesNS);

        if MessageXmlNode <> nil then
        begin
          // these have the same namespace as <MessageXml>
          LineNumberNode := MessageXmlNode.ChildNodes.FindNode(cNodeLineNumber);
          LinePositionNode := MessageXmlNode.ChildNodes.FindNode(cNodeLinePosition);
          ViolationNode := MessageXmlNode.ChildNodes.FindNode(cNodeViolation);
        end;
      end;
      Exit;
   end;

   // this has the same namespace as <Envelope>
   SoapHeaderNode := RootNode.ChildNodes.FindNode(cNodeSOAPHeader);
   Assert(SoapHeaderNode <> nil,'SOAP Header not found');
end;