Question

Can someone please help in recording movements while dragging an object and when the object is dropped the record event will stop and the recorded movement will be animated by Play button.

Answer 1

Set up an array that will store recorded information:

var recording:Array = [];

Set up a method that will add information to this Array:

function record(target:MovieClip):void
{
    recording.push(new Point(target.x, target.y));
}

Do this when you start dragging your object:

recording.length = 0;

addEventListener(Event.ENTER_FRAME, _record);
function _record(e:Event):void
{
    record(yourObject);
}

Do this when you stop dragging your object:

removeEventListener(Event.ENTER_FRAME, _record);

Do this when you click replay:

recording.reverse();

addEventListener(Event.ENTER_FRAME, _playRecording);
function _playRecording(e:Event):void
{
    var step:Point = recording.pop();

    yourObject.x = step.x;
    yourObject.y = step.y;

    if(recording.length < 1)
        removeEventListener(Event.ENTER_FRAME, _playRecording);
}

---

Storing your recorded data for later use:

You can use this method to convert your recording array into a string:

function collapse(data:Array):String
{
    var joined:Array = [];

    for each(var point:Point in data)
    {
        joined.push(Math.round(point.x) + ":" + Math.round(point.y));
    }

    return joined.join("$");
}

Which will end up something like:

trace(collapse(recording)); // 48:47$29:19$4:26$20:35$1:48$3:16$12:24$27:30$0:24$19:48

You’ll then be able to use this to create your recording array:

function expand(data:String):Array
{
    var out:Array = [];
    var base:Array = data.split("$");

    for each(var fragment:String in base)
    {
        var coords:Array = fragment.split(":");
        var point:Point = new Point(coords[0], coords[1]);

        out.push(point);
    }

    return out;
}

Which works like so:

var previousData:String = "48:47$29:19$4:26$20:35$1:48$3:16$12:24$27:30$0:24$19:48";
var recording:Array = expand(previousData);

trace(recording); // (x=48, y=47),(x=29, y=19),(x=4, y=26),(x=20, y=35),(x=1, y=48),(x=3, y=16),(x=12, y=24),(x=27, y=30),(x=0, y=24),(x=19, y=48)