Question

CoffeeScript Source

return sprite: myFunc
  width: 79
  height: 66
throw:
  from: {}
  last: {}

Compiled With CoffeeScript 1.1.1

return {
  sprite: myFunc({
    width: 79,
    height: 66
  }),
  "throw": {
    from: {},
    last: {}
  }
};

Compiled With CoffeeScript 1.3.3

return {
  sprite: myFunc({
    width: 79,
    height: 66
  })
};

({
  "throw": {
    from: {},
    last: {}
  }
});

This breaks my code. I can see nothing in the changelog between versions. Is this a bug?

Answer 1

I’d call it a bug but the bug was in 1.1.1 and in your code for depending on a particular interpretation of ambiguous code. This:

return sprite: myFunc
  width: 79
  height: 66
throw:
  from: {}
  last: {}

may be a little ambiguous as to what block throw is supposed to be in but the 1.3.3 interpretation is the only one that makes sense to me: your indentation doesn’t match your intent.

If we add a function wrapper for clarity:

f = ->
  return sprite: myFunc
    width: 79
    height: 66
  throw:
    from: {}
    last: {}

then what little ambiguity was there vanishes and the 1.3.3 interpretation:

f = ->
  return { sprite: myFunc(width: 79, height: 66) }
  { throw: { from: {}, last: {} } }

makes perfect sense as your structure is just a variation on:

f = ->
  return pancakes
  eggs

Just because braces and parentheses and what not are optional doesn’t mean that they are forbidden. If the intent of a piece of code structure isn’t obvious at a glance then you should force the structure with some braces and parentheses, something like this perhaps:

return { sprite: myFunc
  width: 79
  height: 66
throw:
  from: {}
  last: {}
}

or better (IMO):

return {
  sprite: myFunc(
    width: 79
    height: 66
  )
  throw:
    from: {}
    last: {}
}

Unfortunately, you’re going to have to read all your CoffeeScript and add braces as needed. I hope you have a very good test suite.

---

Interestingly enough, if you drop the return:

sprite: myFunc
  width: 79
  height: 66
throw:
  from: {}
  last: {}

then you get this interpretation in the latest:

{
  sprite: myFunc(...)
  throw:  { from: ... }
}

That makes perfect sense to me as it looks like:

v =
  sprite: myFunc ...
  throw: ...

Your explicit return introduces context that isn’t present when the return is implied.