Question

Currently i am now working on a drag drop application in pure action script project. Now the problem i have is , I have some PNG bitmaps with some transparent background around it.The bitmap may collide each other.User may be able to drag any of these bitmap. if the user clicks on the transparent area , user should not be able drag and vice versa.which means user should be able to drag the top most bitmap ignoring the transparent bitmap..

Can anyone help on this.

Thanks and regards.

Answer 1

It is possible. you need to read more documentation about the possibilities of the AS.

here is just a quick and dirty prove of concept:

package
{
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.geom.Point;

/**
 * ...
 * @author Jevgenij Dmitrijev ( http://www.ifmi.lt )
 *
 */
public class DragTransparentBitmaps extends Sprite
{
    private var _dragMC:Sprite;

    public function DragTransparentBitmaps()
    {
        var sp:Sprite;
        var bmp:Bitmap;

        for (var i:uint; i < 10; ++i)
        {
            sp = new Sprite();
            sp.name = 'item_' + i.toString();
            bmp = new Bitmap(new Close()); // add your bitmapData
            sp.addChild(bmp);
            sp.x = 20*i;
            sp.y = 20*i;
            addChild(sp);
        }

        stage.addEventListener (MouseEvent.MOUSE_DOWN, handleMouseDown )
    }

    function handleMouseDown(e:MouseEvent):void
    {
        /*

        // OPTIONAL:

        // if you need the mouse to be in a specific region:            
        if ( mouseX > 400 || mouseY > 400 )
        {
            return;
        }

        // or you can just check if mouse is on your needed mc:
        if ( !someSprite.hitTestPoint(mouseX, mouseY) )
            return;
        */


        // cheking how much objects are under the mouse
        var objectsUnderMouse:Array = getObjectsUnderPoint (new Point (mouseX, mouseY));

        var length_i:uint = objectsUnderMouse.length;

        if ( length_i > 0 )
        {
            // if only one then no checking needed just parsing it to the drag function.
            if ( length_i == 1 )
            {
                drag(objectsUnderMouse[0].parent);
                return;
            }
        }
        else
            return; // if nothing under the mouse just end the function

        var sp:Sprite;
        var bmpData:BitmapData; 

        for (var i:uint; i < length_i; i++) 
        {
            // taking a sprite where bitmap is positioned
            sp = objectsUnderMouse[i].parent as Sprite;

            // taking the bitmap data
            bmpData = objectsUnderMouse[i].bitmapData;

            // taking the pixel information ( see the docu about it )
            // if the value is > 0 it means that the bitmap is not transparent and we can move it
            if ( bmpData.getPixel32(sp.mouseX, sp.mouseY ) > 0 )
            {
                drag (objectsUnderMouse[i].parent);
                return;
            }
        }
    }

    // just drag functions
    private function drag(value:DisplayObject):void 
    {
        _dragMC = value as Sprite;
        _dragMC.startDrag();

        stage.addEventListener (MouseEvent.MOUSE_UP, handleMouseUp);
    }

    private function handleMouseUp(e:MouseEvent):void 
    {
        stage.removeEventListener (MouseEvent.MOUSE_UP, handleMouseUp);
        _dragMC.stopDrag();
    }
}
}

let me know if it was helpful.