Question

<Data>
<AA>123</AA>
  <AA>45658</AA>
  <AA>123456789</AA> 
</Data>

Output needed:

<info>
  <Numbers id="000000123" />
  <Numbers id="000045658" />
  <Numbers id="123456789" />
</info>

Condition:

I need to check for the string length of value of the element AA. If the length is less than 9 I need to append ‘0’ s to make it 9 digit in length.

XSLT wrote:

<xsl:template match="Data">   
  <info>
       <xsl:for-each select="AA">
              <Numbers>
                <xsl:attribute name="id">
                  <xsl:variable name="numlenght">
                  <xsl:value-of select="string-length(.)" />
                    </xsl:variable>
                  <xsl:choose>
                    <xsl:when test="$numlenght&lt;9">
                      <xsl:variable name="balance">
                        <xsl:value-of select="9-$numlenght"/>
                      </xsl:variable>
                      <xsl:for-each select="//*[position() &lt;$balance]">
                        <xsl:value-of select="'0'"/>
                      </xsl:for-each>

                    </xsl:when>
                                      </xsl:choose>
                  <xsl:value-of select="."/>

                </xsl:attribute>
              </Numbers>
            </xsl:for-each>
  </info>
        </xsl:template>

I am not getting the exact output.

Can any one suggest how to do that?

Answer 1

This requires less memory:

concat(substring('000000000', string-length() +1), .)

Here is a complete transformation:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <info><xsl:apply-templates/></info>
 </xsl:template>

 <xsl:template match="AA">
  <Numbers id="{concat(substring('000000000', string-length() +1), .)}"/>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document:

<Data>
    <AA>123</AA>
    <AA>45658</AA>
    <AA>123456789</AA>
</Data>

the wanted, correct result is produced:

<info>
   <Numbers id="000000123"/>
   <Numbers id="000045658"/>
   <Numbers id="123456789"/>
</info>

Explanation:

The expression:

concat(substring('000000000', string-length() +1), .)

doesn’t construct a string with length greater than 9 (as in another answer, that after this extracts a substring of the longer than 9 characters string).

In contrast, it extracts only the necessary for padding number of 0 characters and then concatenates them to the current node’s string value.

Do note:

This:

  <Numbers id="{concat(substring('000000000', string-length() +1), .)}"/>

can be simplified further to this:

  <Numbers id="{substring('000000000', string-length() +1)}{.}"/>