Question

Delphi Xe, Win7

I need the following function:

Function isPcInDomain:bool;

The domain name does not interest me, msdn LsaQueryInformationPolicy too (Or give realisation on Delphi). I would like to have a function that does no need to query the network.
Also it must still work if the local name of the computer contains a .

Tried to define a domain name, but on the personal computer which not in the domain – as a domain name gives out a name of Local Working group 🙁

Answer 1

You can use NetGetJoinInformation:

program test;

{$APPTYPE CONSOLE}
{$MINENUMSIZE 4}

uses
  Windows, SysUtils;

const
  netapi = 'netapi32.dll';

type
  TNetSetupJoinStatus = (NetSetupUnknownStatus, NetSetupUnjoined, NetSetupWorkgroupName, NetSetupDomainName);

function NetApiBufferFree(Buffer: Pointer): DWORD; stdcall; external netapi;
function NetGetJoinInformation(lpServer: PWideChar; out lpNameBuffer: PWideChar;
  out BufferType: TNetSetupJoinStatus): Cardinal; stdcall; external netapi;

procedure NetApiCheck(RetValue: Cardinal);
begin
  if RetValue <> ERROR_SUCCESS then
    RaiseLastOSError(RetValue);
end;

function GetJoinInfo(out JoinStatus: TNetSetupJoinStatus): WideString;
var
  P: PWideChar;
begin
  NetApiCheck(NetGetJoinInformation(nil, P, JoinStatus));
  Result := P;
  NetApiBufferFree(P);
end;

procedure Main;
const
  JoinStatusStrings: array[TNetSetupJoinStatus] of string = ('Unknown', 'Unjoined', 'Workgroup', 'Domain');
var
  Info: TNetSetupJoinStatus;
  S: WideString;
begin
  S := GetJoinInfo(Info);
  Writeln(Format('%s %s', [JoinStatusStrings[Info], S]));
end;

begin
  try
    Main;
  except
    on E: Exception do
    begin
      ExitCode := 1;
      Writeln(Format('[%s] %s', [E.ClassName, E.Message]));
    end;
  end;
end.