Question

did a search for this and didn’t find an answer, so here goes…

I have some xml similar to the following:

<?xml version="1.0" encoding="utf-8"?>
<footnote ref="1">
    <para>Here is some text about some guy who made
        <emphasis role="italic">fascinating</emphasis> comment I want to quote
        <blockquote> So I went to this place and met this guy....</blockquote>
        It seemed more interesting at the time.
    </para>
</footnote>

I want to use xslt to change it to a new schema (using new namespace prefix)

<?xml version="1.0" encoding="utf-8"?>
<nns:footnote ref="1">
    <nns:fn-para>Here is some text about some guy who made
        <nns:emph type="it">fascinating</nns:emph> comment I want to quote:
    </nns:fn-para>
    <nns:fn-blockquote>
        <nns:bq-para>So I went to this place and met this guy....</nns:bq-para>
    </nns:fn-blockquote>
    <nns:fn-para> It seemed more interesting at the time.</nns:fn-para>
</nns:footnote>

I’ve tried a few things…taking a para that’s a descendant of footnote and looping through the children, but that’s problematic because it isn’t only text nodes in the para, there are also emph tags, and I still don’t know how to place a child node up the tree and over in the result tree…doe that make sense?

Answer 1

EDIT: Small refactor and extended explanation.

This stylesheet:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:nns="nns">
    <xsl:key name="kNodeByPrecedingBlock"
             match="para/node()[not(self::blockquote)]"
             use="generate-id(
                     (..|preceding-sibling::*[self::blockquote][1])[last()]
                  )"/>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="footnote">
        <nns:footnote>
            <xsl:apply-templates select="node()|@*"/>
        </nns:footnote>
    </xsl:template>
    <xsl:template match="para">
        <xsl:apply-templates select=".|blockquote" mode="group"/>
    </xsl:template>
    <xsl:template match="emphasis">
        <nns:emph>
            <xsl:apply-templates select="node()|@*"/>
        </nns:emph>
    </xsl:template>
    <xsl:template match="emphasis/@role">
        <xsl:attribute name="type">
            <xsl:value-of select="substring(.,1,2)"/>
        </xsl:attribute>
    </xsl:template>
    <xsl:template match="blockquote">
        <nns:fn-blockquote>
            <nns:bq-para>
                <xsl:apply-templates/>
            </nns:bq-para>
        </nns:fn-blockquote>
    </xsl:template>
    <xsl:template match="para" mode="group" name="makePara">
        <xsl:variable name="vGroup"
             select="key('kNodeByPrecedingBlock',generate-id())"/>
        <xsl:if test="$vGroup">
            <nns:fn-para>
                <xsl:apply-templates select="$vGroup"/>
            </nns:fn-para>
        </xsl:if>
    </xsl:template>
    <xsl:template match="*" mode="group">
        <xsl:apply-templates select="."/>
        <xsl:call-template name="makePara"/>
    </xsl:template>
</xsl:stylesheet>

Output:

<nns:footnote ref="1" xmlns:nns="nns">
   <nns:fn-para>Here is some text about some guy who made 
      <nns:emph type="it">fascinating</nns:emph> comment I want to quote 
   </nns:fn-para>
   <nns:fn-blockquote>
      <nns:bq-para> So I went to this place and met this guy....</nns:bq-para>
   </nns:fn-blockquote>
   <nns:fn-para>         It seemed more interesting at the time. 
   </nns:fn-para>
</nns:footnote>

Note: Identity rule for overwriting (just for style, but it’s a good pattern). Four direct transformation rules matching footnote, emphasis, @role attribute of emphasis and blockquote. Grouping key matching “inline” para‘s children: the generate id of first preceding “block” element or para parent. Grouping rule for para applying templates to self and “block” elements in "group" mode. Rule matching para in "group" mode (also named makePara): output a paragraph if there is a group with context node generate id as key value. Rule matching any element in "group" mode (it’ll be any “block” element): apply templates to self (“reset” mode) and call makePara named template.